reserve f, g, h for Function;
reserve x, y, z, u, X for set,
  A for non empty set,
  n for Element of NAT,
  f for Function of X, X;
reserve f for c=-monotone Function of bool X, bool X,
  S for Subset of X;
reserve X, Y for non empty set,
  f for Function of X, Y,
  g for Function of Y, X;
reserve L for Lattice,
  f for Function of the carrier of L, the carrier of L,
  x for Element of L,
  O, O1, O2, O3, O4 for Ordinal,
  T for Sequence;
reserve L for complete Lattice,
  f for monotone UnOp of L,
  a, b for Element of L;

theorem Th32:
  for a, b st a is_a_fixpoint_of f & b is_a_fixpoint_of f ex O st
card O c= card the carrier of L & (f, O)+.(a"\/"b) is_a_fixpoint_of f & a [= (f
  , O)+.(a"\/"b) & b [= (f, O)+.(a"\/"b)
proof
  let a, b;
  reconsider ab = a"\/"b as Element of L;
A1: a [= ab by LATTICES:5;
  then
A2: f.a [= f.ab by QUANTAL1:def 12;
A3: b [= ab by LATTICES:5;
  then
A4: f.b [= f.ab by QUANTAL1:def 12;
  assume a is_a_fixpoint_of f & b is_a_fixpoint_of f;
  then
A5: a = f.a & b = f.b;
  then consider O such that
A6: card O c= card the carrier of L & (f, O)+.ab is_a_fixpoint_of f by A2,A4
,Th30,FILTER_0:6;
  take O;
  thus card O c= card the carrier of L & (f, O)+.(a"\/"b) is_a_fixpoint_of f
  by A6;
  ab [= f.ab by A5,A2,A4,FILTER_0:6;
  then
A7: ab [= (f, O)+.(a"\/"b) by Th22;
  hence a [= (f, O)+.(a"\/"b) by A1,LATTICES:7;
  thus thesis by A3,A7,LATTICES:7;
end;
