reserve x, y for object, X for set,
  i, j, k, l, n, m for Nat,
  D for non empty set,
  K for commutative Ring,
  a,b for Element of K,
  perm, p, q for Element of Permutations(n),
  Perm,P for Permutation of Seg n,
  F for Function of Seg n,Seg n,
  perm2, p2, q2, pq2 for Element of Permutations(n+2),
  Perm2 for Permutation of Seg (n+2);
reserve s for Element of 2Set Seg (n+2);
reserve pD for FinSequence of D,
  M for Matrix of n,m,D,
  pK,qK for FinSequence of K,
  A for Matrix of n,K;

theorem Th32:
  for l,pK,qK,perm st l in Seg n & len pK = n & len qK = n for M
  be Matrix of n,K holds (Path_product(RLine(M,l,a*pK+b*qK))).perm = a*(
  Path_product(RLine(M,l,pK))).perm + b*(Path_product(RLine(M,l,qK))).perm
proof
  let l,pK,qK,perm such that
A1: l in Seg n and
A2: len pK = n and
A3: len qK = n;
  set mm=the multF of K;
  let M be Matrix of n,K;
  set Rpq=RLine(M,l,a*pK+b*qK);
  set Rp=RLine(M,l,pK);
  set Rq=RLine(M,l,qK);
  set Ppq=Path_matrix(perm,Rpq);
  set Pathpq=Path_product(Rpq);
  set Pp=Path_matrix(perm,Rp);
  set Pathp=Path_product(Rp);
  set Pq=Path_matrix(perm,Rq);
  set Pathq=Path_product(Rq);
  now
    per cases;
    case
A4:   perm is even;
      then mm $$ Ppq=-(mm $$ Ppq,perm) by MATRIX_1:def 16;
      then
A5:   Pathpq.perm=mm $$ Ppq by MATRIX_3:def 8;
      mm $$ Pq=-(mm $$ Pq,perm) by A4,MATRIX_1:def 16;
      then
A6:   Pathq.perm=mm $$ Pq by MATRIX_3:def 8;
      mm $$ Pp=-(mm $$ Pp,perm) by A4,MATRIX_1:def 16;
      then Pathp.perm=mm $$ Pp by MATRIX_3:def 8;
      hence thesis by A1,A2,A3,A6,A5,Th31;
    end;
    case
A7:   perm is odd;
      then -mm $$ Ppq=-(mm $$ Ppq,perm) by MATRIX_1:def 16;
      then
A8:   Pathpq.perm=-mm$$Ppq by MATRIX_3:def 8;
      -mm $$ Pp=-(mm $$ Pp,perm) by A7,MATRIX_1:def 16;
      then
A9:   Pathp.perm=-mm$$Pp by MATRIX_3:def 8;
A10:  -a*(mm $$ Pp)=a*(-mm $$ Pp) by VECTSP_1:8;
      -mm $$ Pq=-(mm $$ Pq,perm) by A7,MATRIX_1:def 16;
      then
A11:  Pathq.perm=-mm$$Pq by MATRIX_3:def 8;
A12:  -(a*(mm $$ Pp)+b*(mm $$ Pq))=-(a*(mm $$ Pp))-(b*(mm $$ Pq)) by
VECTSP_1:17;
      mm $$ Ppq=a*(mm $$ Pp)+b*(mm $$ Pq) by A1,A2,A3,Th31;
      hence thesis by A9,A11,A8,A10,A12,VECTSP_1:8;
    end;
  end;
  hence thesis;
end;
