reserve R for Ring,
  V for RightMod of R,
  a,b for Scalar of R,
  x,y for set,
  p,q ,r for FinSequence,
  i,k for Nat,
  u,v,v1,v2,v3,w for Vector of V,
  F,G,H for FinSequence of V,
  A,B for Subset of V,
  f for Function of V, R,
  S,T for finite Subset of V;
reserve L,L1,L2,L3 for Linear_Combination of V;
reserve l for Linear_Combination of A;

theorem Th32:
  for l being Linear_Combination of {v} holds Sum(l) = v * l.v
proof
  let l be Linear_Combination of {v};
A1: Carrier(l) c= {v} by Def5;
  now
    per cases by A1,ZFMISC_1:33;
    suppose
      Carrier(l) = {};
      then
A2:   l = ZeroLC(V) by Def4;
      hence Sum(l) = 0.V by Lm3
        .= v * 0.R by VECTSP_2:32
        .= v * l.v by A2,Th18;
    end;
    suppose
      Carrier(l) = {v};
      then consider F such that
A3:   F is one-to-one & rng F = {v} and
A4:   Sum(l) = Sum(l (#) F) by Def7;
      F = <* v *> by A3,FINSEQ_3:97;
      then l (#) F = <* v * l.v *> by Th25;
      hence thesis by A4,RLVECT_1:44;
    end;
  end;
  hence thesis;
end;
