reserve s for State of SCM+FSA,
  I for MacroInstruction of SCM+FSA,
  a for read-write Int-Location;
reserve i,j,k,n for Nat;
reserve P,P1,P2,Q for Instruction-Sequence of SCM+FSA;

theorem Th25:
  for s be State of SCM+FSA
   holds s.(fsloc 0), IExec(insert-sort (fsloc 0),P,s).(fsloc 0)
    are_fiberwise_equipotent &
 for i,j be Nat st i >=1 & j<=len (s.(fsloc 0)) & i<j
 for x1,x2 be Integer st x1 =IExec(insert-sort (fsloc 0),P,s).(fsloc 0).i &
     x2=IExec(insert-sort (fsloc 0),P,s).(fsloc 0).j
  holds x1 >= x2
proof
  let s be State of SCM+FSA;
  set WJ=w2 ";" w3 ";" w4 ";" w5 ";" w6 ";" j1 ";" j2,
     s0=Initialized s,
     s1=Exec(w2, s0),
     s2=IExec(w2 ";" w3,P, s),
     s3=IExec(w2 ";" w3 ";" w4,P,s),
     s4=IExec(w2 ";" w3 ";" w4 ";" w5,P,s),
     s5=IExec(w2 ";" w3 ";" w4 ";" w5 ";" w6,P,s),
     s6=IExec(w2 ";" w3 ";" w4 ";" w5 ";" w6 ";" j1,P,s),
     s7=IExec(WJ,P,s);
A1: s5.f0 =Exec(w6, s4).f0 by SCMFSA6C:7
    .=s4.f0 by SCMFSA_2:63
    .=Exec(w5, s3).f0 by SCMFSA6C:7
    .=s3.f0 by SCMFSA_2:63
    .=Exec(w4, s2).f0 by SCMFSA6C:7
    .=s2.f0 by SCMFSA_2:63
    .=Exec(w3, s1).f0 by SCMFSA6C:9
    .=s1.f0 by SCMFSA_2:63
    .=s0.f0 by SCMFSA_2:63
    .=s.f0 by SCMFSA_M:37;
A2: s6.f0 =Exec(j1, s5).f0 by SCMFSA6C:7
    .=s.f0 by A1,SCMFSA_2:74;
A3: IExec(WJ,P,s).f0 =Exec(j2, s6).f0 by SCMFSA6C:7
    .=s.f0 by A2,SCMFSA_2:65;
A4: IExec(insert-sort f0,P,s).f0=IExec(T1,P,s7).f0 by Lm12,SCM_HALT:21;
A5: s6.b1=Exec(j1, s5).b1 by SCMFSA6C:6
    .=len (s7.f0) by A1,A3,SCMFSA_2:74;
A6: s7.b1=Exec(j2, s6).b1 by SCMFSA6C:6
    .=s6.b1-s6.a0 by SCMFSA_2:65
    .=len (s7.f0) - 1 by A5,SCM_HALT:9;
  hence s.f0, IExec(insert-sort f0,P,s).f0
   are_fiberwise_equipotent by A3,A4,Lm21;
  let i,j be Nat;
  assume that
A7: i>=1 and
A8: j<=len (s.f0) and
A9: i<j;
  thus thesis by A3,A6,A4,A7,A8,A9,Lm21;
end;
