reserve n for Nat,
  a,b for Real,
  s for Real_Sequence;

theorem
  (for n holds s.n = ((n+1)*2|^n)/((n+2)*(n+3))) implies for n holds
  Partial_Sums(s).n = 2|^(n+1)/(n+3)-1/2
proof
  defpred X[Nat] means Partial_Sums(s).$1 =2|^($1+1)/($1+3)-1/2;
  assume
A1: for n holds s.n = ((n+1)*2|^n)/((n+2)*(n+3));
A2: for n st X[n] holds X[n+1]
  proof
    let n;
    n+3>=3 by NAT_1:11;
    then
A3: n+3>0 by XXREAL_0:2;
    n+4>=4 by NAT_1:11;
    then
A4: n+4>0 by XXREAL_0:2;
    assume Partial_Sums(s).n = 2|^(n+1)/(n+3)-1/2;
    then Partial_Sums(s).(n+1) = 2|^(n+1)/(n+3)-1/2 + s.(n+1) by SERIES_1:def 1
      .= 2|^(n+1)/(n+3)-1/2 +((n+1+1)*2|^(n+1))/((n+1+2)*(n+1+3)) by A1
      .= 2|^(n+1)/(n+3) +((n+2)*2|^(n+1))/((n+3)*(n+4))-1/2
      .= (2|^(n+1)*(n+4))/((n+3)*(n+4)) +((n+2)*2|^(n+1))/((n+3)*(n+4))-1/2
    by A4,XCMPLX_1:91
      .= (2|^(n+1)*(n+4)+(n+2)*2|^(n+1))/((n+3)*(n+4))-1/2 by XCMPLX_1:62
      .= (2|^(n+1)*2*(n+3))/((n+4)*(n+3))-1/2
      .= (2|^(n+1)*2)/(n+4)-1/2 by A3,XCMPLX_1:91
      .= 2|^(n+1+1)/(n+1+3)-1/2 by NEWTON:6;
    hence thesis;
  end;
  Partial_Sums(s).0 = s.0 by SERIES_1:def 1
    .=((0+1)*2|^0)/((0+2)*(0+3)) by A1
    .=(1*1)/6 by NEWTON:4
    .=2/3-1/2
    .=2|^(0+1)/(0+3)-1/2;
  then
A5: X[0];
  for n holds X[n] from NAT_1:sch 2(A5,A2);
  hence thesis;
end;
