reserve a,b,c for set;
reserve r for Real,
  X for set,
  n for Element of NAT;

theorem Th32:
  for X being Subset-Family of REAL st card X in continuum ex x
  being Real, q being Rational st x < q & not [.x,q.[ in UniCl X
proof
  let X be Subset-Family of REAL such that
A1: card X in continuum;
  set Z = {x where x is Element of REAL: ex U being set st U in UniCl X & x
  is_local_minimum_of U};
  set z = the Element of REAL \ Z;
  card Z in continuum by A1,Th31;
  then
A2: REAL \ Z <> {} by CARD_1:68;
  then
A3: not z in Z by XBOOLE_0:def 5;
  reconsider z as Element of REAL by A2,XBOOLE_0:def 5;
  z+0 < z+1 by XREAL_1:6;
  then consider q being Rational such that
A4: z < q and
  q < z+1 by RAT_1:7;
  take z, q;
  thus z < q by A4;
  z is_local_minimum_of [.z,q.[
  proof
    thus z in [.z,q.[ by A4,XXREAL_1:3;
    take y = z-1;
    z-0 = z;
    hence y < z by XREAL_1:15;
    assume ].y,z.[ meets [.z,q.[;
    then consider a being object such that
A5: a in ].y,z.[ and
A6: a in [.z,q.[ by XBOOLE_0:3;
    reconsider a as Element of REAL by A5;
    a < z by A5,XXREAL_1:4;
    hence thesis by A6,XXREAL_1:3;
  end;
  hence thesis by A3;
end;
