
theorem Th32:
  for X being monotone-convergence non empty TopSpace, N being
  eventually-directed net of Omega X holds sup N in Lim N
proof
  let X be monotone-convergence non empty TopSpace, N be eventually-directed
  net of Omega X;
  rng netmap (N,Omega X) is directed by WAYBEL_2:18;
  then reconsider
  D = rng the mapping of N as non empty directed Subset of Omega X;
  for V being a_neighborhood of sup N holds N is_eventually_in V
  proof
    let V be a_neighborhood of sup N;
A1: Int V c= V by TOPS_1:16;
A2: the TopStruct of X = the TopStruct of Omega X by Def2;
    then reconsider I = Int V as Subset of X;
A3: I is open by A2,TOPS_3:76;
    sup N in I by CONNSP_2:def 1;
    then Sup the mapping of N in I by WAYBEL_2:def 1;
    then D meets I by A3,Def4;
    then consider y being object such that
A4: y in D and
A5: y in I by XBOOLE_0:3;
    reconsider y as Point of X by A5;
    consider x being object such that
A6: x in dom the mapping of N and
A7: (the mapping of N).x = y by A4,FUNCT_1:def 3;
    reconsider x as Element of N by A6;
    consider j being Element of N such that
A8: for k being Element of N st j <= k holds N.x <= N.k by WAYBEL_0:11;
    take j;
    let k be Element of N;
    assume j <= k;
    then N.x <= N.k by A8;
    then consider Y being Subset of X such that
A9: Y = {N.k} and
A10: N.x in Cl Y by Def2;
    Y meets I by A3,A5,A7,A10,PRE_TOPC:def 7;
    then consider m being object such that
A11: m in Y /\ I by XBOOLE_0:4;
    m in Y by A11,XBOOLE_0:def 4;
    then
A12: m = N.k by A9,TARSKI:def 1;
    m in I by A11,XBOOLE_0:def 4;
    hence thesis by A12,A1;
  end;
  hence thesis by YELLOW_6:def 15;
end;
