reserve x, y, y1, y2 for object;
reserve V for Z_Module;
reserve W, W1, W2 for Submodule of V;
reserve u, v for VECTOR of V;
reserve i, j, k, n for Element of NAT;
reserve V,W for finite-rank free Z_Module;
reserve T for linear-transformation of V,W;

theorem LmStrict11a:
  for R being Ring
  for V being LeftMod of R, W being Subspace of V,
      Ws being strict Subspace of V,
  v being Vector of V st Ws = (Omega).W holds
  v + W = v + Ws
  proof
    let R be Ring;
    let V be LeftMod of R, W be Subspace of V, Ws be strict Subspace of V,
    v be Vector of V such that
    A1: Ws = (Omega).W;
    for x being object holds x in v + W iff x in v + Ws
    proof
      let x be object;
      hereby
        assume B1: x in v + W;
        then reconsider xx = x as Vector of V;
        consider u be Vector of V such that
        B2: xx = v + u & u in W by B1;
        u in Ws by A1,B2;
        hence x in v + Ws by B2;
      end;
      assume B1: x in v + Ws;
      then reconsider xx = x as Vector of V;
      consider u be Vector of V such that
      B2: xx = v + u & u in Ws by B1;
      u in W by A1,B2;
      hence x in v + W by B2;
    end;
    hence thesis by TARSKI:2;
  end;
