reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem Th33:
  for a being Element of C, the bool-sort of S
  for x being boolean object holds
  \nota = 'not' x iff a = x
  proof
    let a be Element of C, the bool-sort of S;
    a in (the Sorts of C).the bool-sort of S;
    then a in BOOLEAN by AOFA_A00:def 32;
    then reconsider b = a as boolean object;
    let x be boolean object;
    hereby
      assume \nota = 'not' x;
      then 'not' b = 'not' x by AOFA_A00:def 32;
      hence a = x;
    end;
    assume a = x;
    hence \nota = 'not' x by AOFA_A00:def 32;
  end;
