
theorem Th33: ::  WWA3_0:
  for X being set, B being Subset-Family of X, F being
  Dependency-set of X holds X deps_encl_by B is full_family
proof
  let X be set, B be Subset-Family of X, F be Dependency-set of X;
  set F = X deps_encl_by B;
  per cases;
  suppose
A1: B is empty;
    now
      let x be object;
      thus x in F implies x in Dependencies X;
      assume x in Dependencies X;
      then consider x1, x2 being object such that
A2:   x1 in bool X and
A3:   x2 in bool X and
A4:   x = [x1, x2] by ZFMISC_1:def 2;
      reconsider x1,x2 as set by TARSKI:1;
      for g being set st g in B & x1 c= g holds x2 c= g by A1;
      hence x in F by A2,A3,A4;
    end;
    then F = Dependencies X by TARSKI:2;
    then F is (F1) (F2) (F3) (F4) by Th19;
    hence thesis;
  end;
  suppose
    B is non empty;
    then reconsider B as non empty Subset-Family of X;
    thus F is (F1)
    proof
      let A be Subset of X;
      for c being set st c in B & A c= c holds A c= c;
      hence thesis;
    end;
A5: now
      let x,y be Subset of X, c be Element of B;
      assume that
A6:   [x, y] in F and
A7:   x c= c;
      consider a, b being Subset of X such that
A8:   [x,y] = [a,b] and
A9:   for c being set st c in B & a c= c holds b c= c by A6;
A10:  y = b by A8,XTUPLE_0:1;
      x = a by A8,XTUPLE_0:1;
      hence y c= c by A7,A9,A10;
    end;
    now
      let a, b, c be Subset of X such that
A11:  [a, b] in F and
A12:  [b, c] in F;
      now
        let x be set;
        assume that
A13:    x in B and
A14:    a c= x;
        b c= x by A5,A11,A13,A14;
        hence c c= x by A5,A12,A13;
      end;
      hence [a, c] in F;
    end;
    hence F is (F2) by Th18;
    thus F is (F3)
    proof
      let a, b, a9, b9 be Subset of X such that
A15:  [a, b] in F and
A16:  [a, b] >= [a9, b9];
A17:  b9 c= b by A16;
A18:  a c= a9 by A16;
      now
        let c be set;
        assume that
A19:    c in B and
A20:    a9 c= c;
        a c= c by A18,A20;
        then b c= c by A5,A15,A19;
        hence b9 c= c by A17;
      end;
      hence thesis;
    end;
    thus F is (F4)
    proof
      let a, b, a9, b9 be Subset of X such that
A21:  [a, b] in F and
A22:  [a9, b9] in F;
      now
        let c be set;
        assume that
A23:    c in B and
A24:    a\/a9 c= c;
        a9 c= c by A24,XBOOLE_1:11;
        then
A25:    b9 c= c by A5,A22,A23;
        a c= c by A24,XBOOLE_1:11;
        then b c= c by A5,A21,A23;
        hence b\/b9 c= c by A25,XBOOLE_1:8;
      end;
      hence thesis;
    end;
  end;
end;
