reserve Y for non empty set;
reserve B for Subset of Y;

theorem
  for a being Function of Y,BOOLEAN,PA being a_partition of Y
  holds a '<' B_SUP(a,PA)
proof
  let a be Function of Y,BOOLEAN;
  let PA be a_partition of Y;
 a 'imp' B_SUP(a,PA) = I_el Y
  proof
    let y be Element of Y;
    per cases;
    suppose
      ex x being Element of Y st x in EqClass(y,PA) & a.x=TRUE;
      then (B_SUP(a,PA)).y = TRUE by Def17;
      then (B_SUP(a,PA)).y = (I_el Y).y by Def11;
      then ('not' a.y) 'or' (B_SUP(a,PA)).y = ('not' a).y 'or' (I_el Y).y by
MARGREL1:def 19
        .= ('not' a 'or' I_el Y).y by Def4
        .= (I_el Y).y by Th9;
      hence thesis by Def8;
    end;
    suppose
A1:   not (ex x being Element of Y st x in EqClass(y,PA) & a.x=TRUE);
      a.y<>TRUE by A1,EQREL_1:def 6;
      then a.y=FALSE by XBOOLEAN:def 3;
      then ('not' a.y) 'or' (B_SUP(a,PA)).y = (I_el Y).y 'or' (B_SUP(a,PA)).y
      by Def11
        .= ((I_el Y) 'or' B_SUP(a,PA)).y by Def4
        .= (I_el Y).y by Th9;
      hence thesis by Def8;
    end;
  end;
  hence thesis by Th15;
end;
