reserve Y for non empty set;

theorem
  for a,b being Function of Y,BOOLEAN holds (a 'imp' b) 'imp' (
  'not' a 'or' b)=I_el(Y)
proof
  let a,b be Function of Y,BOOLEAN;
  for x being Element of Y holds ((a 'imp' b) 'imp' ('not' a 'or' b)).x= TRUE
  proof
    let x be Element of Y;
    ((a 'imp' b) 'imp' ('not' a 'or' b)).x ='not' (a 'imp' b).x 'or' (
    'not' a 'or' b).x by BVFUNC_1:def 8
      .='not'( 'not' a.x 'or' b.x) 'or' ('not' a 'or' b).x by
BVFUNC_1:def 8
      .=('not' 'not' a.x '&' 'not' b.x) 'or' (('not' a).x 'or' b.x) by
BVFUNC_1:def 4
      .=('not' a.x 'or' b.x) 'or' (a.x '&' 'not' b.x) by
MARGREL1:def 19
      .=(('not' a.x 'or' b.x) 'or' a.x) '&' (('not' a.x 'or' b.x)
    'or' 'not' b.x) by XBOOLEAN:9
      .=(('not' a.x 'or' a.x) 'or' b.x) '&' ('not' a.x 'or' (b.x
    'or' 'not' b.x))
      .=(TRUE 'or' b.x) '&' ('not' a.x 'or' (b.x 'or' 'not' b.x)) by
XBOOLEAN:102
      .=TRUE '&' ('not' a.x 'or' TRUE) by XBOOLEAN:102
      .=TRUE;
    hence thesis;
  end;
  hence thesis by BVFUNC_1:def 11;
end;
