reserve Al for QC-alphabet;
reserve a,b,c,d for object,
  i,j,k,m,n for Nat,
  p,q,r for Element of CQC-WFF(Al),
  x,y,y0 for bound_QC-variable of Al,
  X for Subset of CQC-WFF(Al),
  A for non empty set,
  J for interpretation of Al,A,
  v,w for Element of Valuations_in(Al,A),
  Sub for CQC_Substitution of Al,
  f,f1,g,h,h1 for FinSequence of CQC-WFF(Al);
reserve fin,fin1 for FinSequence;
reserve PR,PR1 for FinSequence of [:set_of_CQC-WFF-seq(Al),Proof_Step_Kinds:];
reserve a for Element of A;

theorem Th33:
  Suc(f) is_tail_of Ant(f) implies |- f
proof
  set PR = <*[f,0]*>;
A1: rng PR = {[f,0]} by FINSEQ_1:38;
  now
    let a be object;
    assume a in rng PR;
    then
A2: a = [f,0] by A1,TARSKI:def 1;
    f in set_of_CQC-WFF-seq(Al) by Def6;
    hence a in [:set_of_CQC-WFF-seq(Al),Proof_Step_Kinds:] by A2,CQC_THE1:21
,ZFMISC_1:87;
  end;
  then rng PR c= [:set_of_CQC-WFF-seq(Al),Proof_Step_Kinds:];
  then reconsider
  PR as FinSequence of [:set_of_CQC-WFF-seq(Al),Proof_Step_Kinds :] by
FINSEQ_1:def 4;
  assume
A3: Suc(f) is_tail_of Ant(f);
  now
    let n be Nat such that
A4: 1 <= n and
A5: n <= len PR;
    n <= 1 by A5,FINSEQ_1:39;
    then n = 1 by A4,XXREAL_0:1;
    then PR.n = [f,0];
    then (PR.n)`1 = f & (PR.n)`2 = 0;
    hence PR,n is_a_correct_step by A3,Def7;
  end;
  then
A6: PR is a_proof;
  PR.1 = [f,0];
  then PR.(len PR) = [f,0] by FINSEQ_1:40;
  then (PR.(len PR))`1 = f;
  hence thesis by A6;
end;
