reserve

  k,n for Nat,
  x,y,X,Y,Z for set;

theorem Th33:
  for k being Nat for X being non empty set st 2 <= k &
  k + 2 c= card X for F being IncProjMap over G_(k,X), G_(k,X) st F is
  automorphism holds ex s being Permutation of X st the IncProjMap of F =
  incprojmap(k,s)
proof
  let k be Nat;
  let X be non empty set such that
A1: 2 <= k and
A2: k + 2 c= card X;
  defpred P[Nat] means 1 <= $1 & $1 <= k implies for F being
IncProjMap over G_($1,X), G_($1,X) st F is automorphism ex f being Permutation
  of X st the IncProjMap of F = incprojmap($1,f);
A3: for i being Nat st P[i] holds P[i+1]
  proof
    let i be Nat such that
A4: P[i];
    1 <= i + 1 & i + 1 <= k implies for F being IncProjMap over G_(i+1,X),
G_(i+1,X) st F is automorphism ex f being Permutation of X st the IncProjMap of
    F = incprojmap(i+1,f)
    proof
      assume that
      1 <= i + 1 and
A5:   i + 1 <= k;
      let F2 be IncProjMap over G_(i+1,X), G_(i+1,X) such that
A6:   F2 is automorphism;
      (i + 1) + 2 <= k + 2 by A5,XREAL_1:7;
      then
A7:   Segm(i + 3) c= Segm(k + 2) by NAT_1:39;
      then
A8:   i + 3 c= card X by A2;
A9:   i = 0 implies ex f being Permutation of X st the IncProjMap of F2 =
      incprojmap(i+1,f)
      proof
        i + 2 <= i + 3 by XREAL_1:7;
        then Segm(i + 2) c= Segm(i + 3) by NAT_1:39;
        then
A10:    (i + 1) + 1 c= card X by A8;
        assume i = 0;
        hence thesis by A6,A10,Th24;
      end;
      0 < i implies ex f being Permutation of X st the IncProjMap of F2 =
      incprojmap(i+1,f)
      proof
        assume
A11:    0 < i;
        then consider F1 being IncProjMap over G_(i,X), G_(i,X) such that
A12:    F1 is automorphism and
A13:    the line-map of F1 = the point-map of F2 and
        for A being POINT of G_(i,X), B being finite set st B = A holds F1
        . A = meet(F2.:(^^(B,X,i+1))) by A2,A6,A7,Th31,XBOOLE_1:1;
        0 + 1 < i + 1 by A11,XREAL_1:8;
        then consider f being Permutation of X such that
A14:    the IncProjMap of F1 = incprojmap(i,f) by A4,A5,A12,NAT_1:13;
        the IncProjMap of F2 = incprojmap(i+1,f) by A2,A6,A7,A11,A13,A14,Th32,
XBOOLE_1:1;
        hence thesis;
      end;
      hence thesis by A9;
    end;
    hence thesis;
  end;
A15: P[0];
  for i being Nat holds P[i] from NAT_1:sch 2(A15,A3);
  then
A16: P[k];
  let F be IncProjMap over G_(k,X), G_(k,X);
  assume F is automorphism;
  hence thesis by A1,A16,XXREAL_0:2;
end;
