reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem Th33:
  for M being Matrix of D for p being FinSequence of D* st len p =
len M & p.1 = M.1 & (for k st k >= 1 & k < len M holds p.(k+1) = (p.k) ^ M.(k+1
)) holds for i,j st i in dom p & j in dom p & i <= j holds for l st l in dom(p.
  i) holds (p.i).l = (p.j).l
proof
  let M be Matrix of D;
  let p be FinSequence of D* such that
A1: len p = len M and
A2: p.1 = M.1 and
A3: for k st k >= 1 & k < len M holds p.(k+1) = (p.k) ^ M.(k+1);
  defpred P[Nat] means
$1 in dom p implies for i st i in dom p & i
  <=$1 holds (for l st l in dom(p.i) holds (p.i).l = (p.$1).l);
A4: for j st P[j] holds P[j+1]
  proof
    let j such that
A5: j in dom p implies for i st i in dom p & i<=j holds for l st l in
    dom(p.i) holds(p.i).l=(p.j).l;
    assume
A6: j+1 in dom p;
    then
A7: j+1 <= len p by FINSEQ_3:25;
    j+1 >= 1 by A6,FINSEQ_3:25;
    then
A8: j+1 = 1 or j+1 > 1 by XXREAL_0:1;
    let i such that
A9: i in dom p and
A10: i<=j+1;
    i in Seg len p by A9,FINSEQ_1:def 3;
    then
A11: i >= 1 by FINSEQ_1:1;
    per cases by A8,NAT_1:13;
    suppose
      j+1 = 1;
      hence thesis by A10,A11,XXREAL_0:1;
    end;
    suppose
A12:  j >= 1;
A13:  j < len p by A7,NAT_1:13;
      then
A14:  j in Seg len p by A12,FINSEQ_1:1;
      then
A15:  j in dom p by FINSEQ_1:def 3;
      thus for l st l in dom(p.i) holds (p.i).l=(p.(j+1)).l
      proof
        let l such that
A16:    l in dom(p.i);
        per cases by A10,NAT_1:8;
        suppose
A17:      i <= j;
          then
A18:      dom(p.i) c= dom(p.j) by A1,A2,A3,A9,A15,Th30;
          thus (p.i).l=(p.j).l by A5,A9,A14,A16,A17,FINSEQ_1:def 3
            .= (p.(j+1)).l by A1,A3,A12,A13,A16,A18,Th32;
        end;
        suppose
          i = j+1;
          hence thesis;
        end;
      end;
    end;
  end;
A19: P[0];
  for j holds P[j] from NAT_1:sch 2(A19,A4);
  hence thesis;
end;
