reserve E, x, y, X for set;
reserve A, B, C for Subset of E^omega;
reserve a, a1, a2, b for Element of E^omega;
reserve i, k, l, m, n for Nat;

theorem Th33:
  k <= l implies (A |^.. n) ^^ (A |^ (k, l)) = A |^.. (n + k)
proof
  assume
A1: k <= l;
A2: A |^.. (n + k) c= (A |^.. n) ^^ (A |^ (k, l))
  proof
    let x be object;
    assume x in A |^.. (n + k);
    then consider i such that
A3: i >= n + k and
A4: x in A |^ i by Th2;
    consider m such that
A5: n + k + m = i by A3,NAT_1:10;
    i = n + m + k by A5;
    then x in (A |^ (n + m)) ^^ (A |^ k) by A4,FLANG_1:33;
    then
A6: ex a, b st a in A |^ (n + m) & b in A |^ k & x = a ^ b by FLANG_1:def 1;
A7: A |^ (n + m) c= A |^.. n by Th3,NAT_1:11;
    A |^ k c= A |^ (k, l) by A1,FLANG_2:20;
    hence thesis by A6,A7,FLANG_1:def 1;
  end;
  (A |^.. n) ^^ (A |^ (k, l)) c= A |^.. (n + k)
  proof
    let x be object;
    assume x in (A |^.. n) ^^ (A |^ (k, l));
    then consider a, b such that
A8: a in A |^.. n and
A9: b in A |^ (k, l) and
A10: x = a ^ b by FLANG_1:def 1;
    A |^ (k, l) c= A |^.. k by Th6;
    then a ^ b in (A |^.. n) ^^ (A |^.. k) by A8,A9,FLANG_1:def 1;
    hence thesis by A10,Th18;
  end;
  hence thesis by A2,XBOOLE_0:def 10;
end;
