reserve D for non empty set;
reserve f1,f2 for FinSequence of D;
reserve i,n,n1,n2,n3,n4,n5,n6 for Element of NAT;
reserve S for Gene-Set;
reserve p1,p2 for Individual of S;

theorem Th33:
  (n1 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4) = crossover(
  p1,p2,n2,n3,n4)) & (n2 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4) =
crossover(p1,p2,n1,n3,n4)) & (n3 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4)
= crossover(p1,p2,n1,n2,n4)) & (n4 >= len p1 implies crossover(p1,p2,n1,n2,n3,
  n4) = crossover(p1,p2,n1,n2,n3))
proof
A1: n4 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n1,
  n2,n3)
  proof
    assume n4 >= len p1;
    then n4 >= len S by Def1;
    then
A2: n4 >= len crossover(p1,p2,n1,n2,n3) by Def1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(crossover(p1,p2,n1,n2,n3),
    crossover(p2,p1,n1,n2,n3),n4);
    hence thesis by A2,Th5;
  end;
A3: n2 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n1,
  n3,n4)
  proof
    assume
A4: n2 >= len p1;
    then n2 >= len S by Def1;
    then
A5: n2 >= len p2 by Def1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(crossover(p1,p2,n1,n3),
    crossover(p2,p1,n1,n2,n3),n4) by A4,Th19
      .=crossover(crossover(p1,p2,n1,n3),crossover(p2,p1,n1,n3),n4) by A5,Th19;
    hence thesis;
  end;
A6: n3 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n1,
  n2,n4)
  proof
    assume
A7: n3 >= len p1;
    then n3 >= len S by Def1;
    then
A8: n3 >= len p2 by Def1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(crossover(p1,p2,n1,n2),
    crossover(p2,p1,n1,n2,n3),n4) by A7,Th20
      .=crossover(crossover(p1,p2,n1,n2),crossover(p2,p1,n1,n2),n4) by A8,Th20;
    hence thesis;
  end;
  n1 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n2,
  n3,n4)
  proof
    assume
A9: n1 >= len p1;
    then n1 >= len S by Def1;
    then
A10: n1 >= len p2 by Def1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(crossover(p1,p2,n2,n3),
    crossover(p2,p1,n1,n2,n3),n4) by A9,Th18
      .=crossover(crossover(p1,p2,n2,n3),crossover(p2,p1,n2,n3),n4) by A10,Th18
;
    hence thesis;
  end;
  hence thesis by A3,A6,A1;
end;
