reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th33:
  1 <= i & i+1 <= len G implies 1/2*(G*(i,1)+G*(i+1,1))-|[0,1]| in
  Int cell(G,i,0)
proof
  assume that
A1: 1 <= i and
A2: i+1 <= len G;
  set r1 = G*(i,1)`1, s1 = G*(i,1)`2, r2 = G*(i+1,1)`1;
  width G <> 0 by MATRIX_0:def 10;
  then
A3: 1 <= width G by NAT_1:14;
  width G <> 0 by MATRIX_0:def 10;
  then
A4: 1 <= width G by NAT_1:14;
  i < i+1 by XREAL_1:29;
  then
A5: r1 < r2 by A1,A2,A4,GOBOARD5:3;
  then r1+r1 < r1+r2 by XREAL_1:6;
  then
A6: 1/2*(r1+r1) < 1/2*(r1+r2) by XREAL_1:68;
  i < len G by A2,NAT_1:13;
  then
A7: G*(1,1)`2 = s1 by A1,A3,GOBOARD5:1;
  then s1 < G*(1,1)`2+1 by XREAL_1:29;
  then
A8: s1-1 < G*(1,1)`2 by XREAL_1:19;
  1 <= i+1 by NAT_1:11;
  then G*(1,1)`2 = G*(i+1,1)`2 by A2,A3,GOBOARD5:1;
  then G*(i,1) = |[r1,s1]| & G*(i+1,1) = |[r2,s1]| by A7,EUCLID:53;
  then 1/2*(s1+s1) = s1 & G*(i,1)+G*(i+1,1) = |[r1+r2,s1+s1]| by EUCLID:56;
  then 1/2*(G*(i,1)+G*(i+1,1))= |[1/2*(r1+r2),s1]| by EUCLID:58;
  then
A9: 1/2*(G*(i,1)+G*(i+1,1))-|[0,1]| = |[1/2*(r1+r2)-0,s1-1]| by EUCLID:62
    .= |[1/2*(r1+r2),s1-1]|;
  r1+r2 < r2+r2 by A5,XREAL_1:6;
  then
A10: 1/2*(r1+r2) < 1/2*(r2+r2) by XREAL_1:68;
  i < len G by A2,NAT_1:13;
  then
  Int cell(G,i,0) = { |[r,s]| : G*(i,1)`1 < r & r < G*(i+1,1)`1 & s < G*(
  1,1)`2 } by A1,Th24;
  hence thesis by A9,A6,A10,A8;
end;
