reserve Al for QC-alphabet;
reserve b,c,d for set,
  X,Y for Subset of CQC-WFF(Al),
  i,j,k,m,n for Nat,
  p,p1,q,r,s,s1 for Element of CQC-WFF(Al),
  x,x1,x2,y,y1 for bound_QC-variable of Al,
  A for non empty set,
  J for interpretation of Al, A,
  v for Element of Valuations_in(Al,A),
  f1,f2 for FinSequence of CQC-WFF(Al),
  CX,CY,CZ for Consistent Subset of CQC-WFF(Al),
  JH for Henkin_interpretation of CX,
  a for Element of A,
  t,u for QC-symbol of Al;
reserve L for PATH of q,p,
  F1,F3 for QC-formula of Al,
  a for set;
reserve C,D for Element of [:CQC-WFF(Al),bool bound_QC-variables(Al):];
reserve K,L for Subset of bound_QC-variables(Al);
reserve C,D for Subset of CQC-WFF(Al);

theorem Th33:
  ( Al is countable &
  CX is with_examples ) implies ( ex CY st CX c= CY &
  CY is negation_faithful & CY is with_examples )
proof
  assume A1: Al is countable;
  assume
A2: CX is with_examples;
  CQC-WFF(Al) is non empty & CQC-WFF(Al) is countable by Th19,A1;
  then consider f being Function such that
A3: dom f = NAT and
A4: CQC-WFF(Al) = rng f by Lm1;
  reconsider f as sequence of CQC-WFF(Al) by A3,A4,FUNCT_2:2;
  defpred P[set,set,set] means
  ex X st X = $2 \/ {f.$1} & (X is Consistent implies $3 = X) &
  (not X is Consistent implies $3 = $2);
A5: for n being Nat for C ex D st P[n,C,D]
  proof
    let n be Nat;
    reconsider p = f.n as Element of CQC-WFF(Al);
    let C;
    set X = C \/ {p};
    reconsider X as Subset of CQC-WFF(Al);
    not X is Consistent implies ex D st D = C &
    ex X st X = C \/ {p} & (X is Consistent implies D = X) &
    (not X is Consistent implies D = C);
    hence thesis;
  end;
  consider h being sequence of bool CQC-WFF(Al) such that
A6: h.0 = CX &
   for n being Nat holds P[n,h.n,h.(n+1)] from RECDEF_1:sch 2(A5);
  set CY = union rng h;
A7: now
    let a be object such that
A8: a in CX;
    dom h = NAT by FUNCT_2:def 1;
    then h.0 in rng h by FUNCT_1:3;
    hence a in union rng h by A6,A8,TARSKI:def 4;
  end;
  then
A9: CX c= CY;
A10: for n holds h.n c= h.(n+1)
  proof
    let n;
    let a be object such that
A11: a in h.n;
    reconsider p = f.n as Element of CQC-WFF(Al);
    set X = h.n \/ {p};
    reconsider X as Subset of CQC-WFF(Al);
A12: h.n c= X by XBOOLE_1:7;
    ex Y st Y = h.n \/ {f.n} & (Y is Consistent implies h.(n+1) = Y) &
    (not Y is Consistent implies h.(n+1) = h.n) by A6;
    hence thesis by A11,A12;
  end;
A13: for n,m st m in dom h & n in dom h & n < m holds h.n c= h.m
  proof
    let n,m such that
    m in dom h and n in dom h and
A14: n < m;
    defpred P[Nat] means n <= $1 implies h.n c= h.$1;
A15: P[0]
    proof
      assume n <= 0;
      then n = 0 by NAT_1:2;
      hence thesis;
    end;
A16: for k st P[k] holds P[k+1]
    proof
      let k such that
A17:  P[k];
      assume
A18:  n <= k+1;
      now
        assume
A19:    n <= k;
        h.k c= h.(k+1) by A10;
        hence thesis by A17,A19;
      end;
      hence thesis by A18,NAT_1:8;
    end;
    for k holds P[k] from NAT_1:sch 2(A15,A16);
    hence thesis by A14;
  end;
  defpred P[Nat] means h.$1 is Consistent;
A20: P[0] by A6;
A21: for k st P[k] holds P[k+1]
  proof
    let n such that
A22: P[n];
    ex Y st Y = h.n \/ {f.n} & (Y is Consistent implies h.(n+1) = Y) &
    (not Y is Consistent implies h.(n+1) = h.n) by A6;
    hence thesis by A22;
  end;
  set CY = union rng h;
  for n holds P[n] from NAT_1:sch 2(A20,A21);
  then for n,m st m in dom h & n in dom h & n < m holds h.n is Consistent &
  h.n c= h.m by A13;
  then reconsider CY as Consistent Subset of CQC-WFF(Al) by HENMODEL:11;
A23: CY is negation_faithful
  proof
    let p;
    consider a being object such that
A24: a in dom f and
A25: f.a = p by A4,FUNCT_1:def 3;
    reconsider n = a as Nat by A24;
    now
      assume not CY |- 'not' p;
      then
A26:  not CY \/ {p} is Inconsistent by HENMODEL:10;
A27:  now
        assume h.n \/ {p} is Inconsistent;
        then
A28:    h.n \/ {p} |- 'not' VERUM(Al) by Th24;
        now
          let a be object such that
A29:      a in h.n;
A30:       n in NAT by ORDINAL1:def 12;
          dom h = NAT by FUNCT_2:def 1;
          then h.n in rng h by FUNCT_1:3,A30;
          hence a in CY by A29,TARSKI:def 4;
        end;
        then h.n c= CY;
        then CY \/ {p} |- 'not' VERUM(Al) by A28,Th32,XBOOLE_1:9;
        hence contradiction by A26,Th24;
      end;
A31:  ex Y st Y = h.n \/ {f.n} & (Y is Consistent implies h.(n+1) = Y) &
      (not Y is Consistent implies h.(n+1) = h.n) by A6;
      now
        let a be object such that
A32:    a in h.(n+1);
        dom h = NAT by FUNCT_2:def 1;
        then h.(n+1) in rng h by FUNCT_1:3;
        hence a in CY by A32,TARSKI:def 4;
      end;
      then
A33:  h.(n+1) c= CY;
      {p} c= h.(n+1) by A25,A27,A31,XBOOLE_1:7;
      then {p} c= CY by A33;
      then p in CY by ZFMISC_1:31;
      hence CY |- p by Th21;
    end;
    hence thesis;
  end;
A34: CY is with_examples
  proof
    let x,p;
    consider y such that
A35: CX |- ('not' Ex(x,p)) 'or' (p.(x,y)) by A2;
    take y;
    thus thesis by A9,A35,Th32;
  end;
  take CY;
  thus thesis by A7,A23,A34;
end;
