reserve i, I for set,
  f, g, h for Function,
  s for ManySortedSet of I;
reserve G1, G2, G3 for non empty multMagma,
  x1, x2 for Element of G1,
  y1, y2 for Element of G2,
  z1, z2 for Element of G3;
reserve G1, G2, G3 for Group-like non empty multMagma;

theorem
  1_product <*G1,G2,G3*> = <*1_G1,1_G2,1_G3*>
proof
  set s = <*1_G1,1_G2,1_G3*>, f = <*G1,G2,G3*>;
  dom s = {1,2,3} by FINSEQ_1:89,FINSEQ_3:1;
  then reconsider s as ManySortedSet of {1,2,3} by PARTFUN1:def 2
,RELAT_1:def 18;
  for i being set st i in {1,2,3} ex G being Group-like non empty
  multMagma  st G = f.i & s.i = 1_G
  proof
    let i be set such that
A1: i in {1,2,3};
    per cases by A1,ENUMSET1:def 1;
    suppose
A2:   i = 1;
      then reconsider G = f.i as Group-like non empty multMagma;
      take G;
      thus thesis by A2;
    end;
    suppose
A3:   i = 2;
      then reconsider G = f.i as Group-like non empty multMagma;
      take G;
      thus thesis by A3;
    end;
    suppose
A4:   i = 3;
      then reconsider G = f.i as Group-like non empty multMagma;
      take G;
      thus thesis by A4;
    end;
  end;
  hence thesis by Th5;
end;
