reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th33:
  for sn being Real,p being Point of TOP-REAL 2 holds |.(sn
  -FanMorphW).p.|=|.p.|
proof
  let sn be Real,p be Point of TOP-REAL 2;
  set z=(sn-FanMorphW).p;
  reconsider q=p,qz=z as Point of TOP-REAL 2;
  per cases;
  suppose
A1: q`2/|.q.|>=sn & q`1<0;
    then
A2: (sn-FanMorphW).q= |[ |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2)), |.q.|
    * ((q`2/|.q.|-sn)/(1-sn))]| by Th16;
    then
A3: qz`1= |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2)) by EUCLID:52;
A4: qz`2= |.q.|* ((q`2/|.q.|-sn)/(1-sn)) by A2,EUCLID:52;
A5: (q`2/|.q.|-sn)>=0 by A1,XREAL_1:48;
A6: (|.q.|)^2 =(q`1)^2+(q`2)^2 by JGRAPH_3:1;
    |.q.|<>0 by A1,JGRAPH_2:3,TOPRNS_1:24;
    then
A7: (|.q.|)^2>0 by SQUARE_1:12;
    0<=(q`1)^2 by XREAL_1:63;
    then 0+(q`2)^2<=(q`1)^2+(q`2)^2 by XREAL_1:7;
    then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by A6,XREAL_1:72;
    then (q`2)^2/(|.q.|)^2 <= 1 by A7,XCMPLX_1:60;
    then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
    then 1>=q`2/|.q.| by SQUARE_1:51;
    then
A8: 1-sn>=q`2/|.q.|-sn by XREAL_1:9;
    per cases;
    suppose
A9:   1-sn=0;
A10:  ((q`2/|.q.|-sn)/(1-sn))=(q`2/|.q.|-sn)*(1-sn)" by XCMPLX_0:def 9
        .= (q`2/|.q.|-sn)*0 by A9
        .=0;
      then -sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2)=-1;
      then (sn-FanMorphW).q= |[|.q.|*(-1),|.q.|*0]| by A1,A10,Th16
        .=|[-(|.q.|),0]|;
      then ((sn-FanMorphW).q)`1=-(|.q.|) & ((sn-FanMorphW).q)`2=0 by EUCLID:52;
      then |.(sn-FanMorphW).p.|=sqrt((-(|.q.|))^2+0^2) by JGRAPH_3:1
        .=sqrt((|.q.|)^2)
        .=|.q.| by SQUARE_1:22;
      hence thesis;
    end;
    suppose
A11:  1-sn<>0;
      per cases by A11;
      suppose
A12:    1-sn>0;
        -(1-sn)<= -( q`2/|.q.|-sn) by A8,XREAL_1:24;
        then (-(1-sn))/(1-sn)<=(-( q`2/|.q.|-sn))/(1-sn) by A12,XREAL_1:72;
        then -1<=(-( q`2/|.q.|-sn))/(1-sn) by A12,XCMPLX_1:197;
        then ((-(q`2/|.q.|-sn))/(1-sn))^2<=1^2 by A5,A12,SQUARE_1:49;
        then 1-((-(q`2/|.q.|-sn))/(1-sn))^2>=0 by XREAL_1:48;
        then
A13:    1-(-((q`2/|.q.|-sn))/(1-sn))^2>=0 by XCMPLX_1:187;
A14:    (qz`1)^2= (|.q.|)^2*(sqrt(1-((q`2/|.q.|-sn)/(1-sn))^2))^2 by A3
          .= (|.q.|)^2*(1-((q`2/|.q.|-sn)/(1-sn))^2) by A13,SQUARE_1:def 2;
        (|.qz.|)^2=(qz`1)^2+(qz`2)^2 by JGRAPH_3:1
          .=(|.q.|)^2 by A4,A14;
        then sqrt((|.qz.|)^2)=|.q.| by SQUARE_1:22;
        hence thesis by SQUARE_1:22;
      end;
      suppose
A15:    1-sn<0;
        0+(q`2)^2<(q`1)^2+(q`2)^2 by A1,SQUARE_1:12,XREAL_1:8;
        then (q`2)^2/(|.q.|)^2 < (|.q.|)^2/(|.q.|)^2 by A7,A6,XREAL_1:74;
        then (q`2)^2/(|.q.|)^2 < 1 by A7,XCMPLX_1:60;
        then ((q`2)/|.q.|)^2 < 1 by XCMPLX_1:76;
        then
A16:    1 > q`2/|.p.| by SQUARE_1:52;
        q`2/|.q.|-sn>=0 by A1,XREAL_1:48;
        hence thesis by A15,A16,XREAL_1:9;
      end;
    end;
  end;
  suppose
A17: q`2/|.q.|<sn & q`1<0;
    then |.q.|<>0 by JGRAPH_2:3,TOPRNS_1:24;
    then
A18: (|.q.|)^2>0 by SQUARE_1:12;
A19: (q`2/|.q.|-sn)<0 by A17,XREAL_1:49;
A20: (|.q.|)^2 =(q`1)^2+(q`2)^2 by JGRAPH_3:1;
    0<=(q`1)^2 by XREAL_1:63;
    then 0+(q`2)^2<=(q`1)^2+(q`2)^2 by XREAL_1:7;
    then (q`2)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by A20,XREAL_1:72;
    then (q`2)^2/(|.q.|)^2 <= 1 by A18,XCMPLX_1:60;
    then ((q`2)/|.q.|)^2 <= 1 by XCMPLX_1:76;
    then -1<=q`2/|.q.| by SQUARE_1:51;
    then
A21: -1-sn<=q`2/|.q.|-sn by XREAL_1:9;
A22: (sn-FanMorphW).q= |[ |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2)), |.q
    .|* ((q`2/|.q.|-sn)/(1+sn))]| by A17,Th17;
    then
A23: qz`1= |.q.|*(-sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2)) by EUCLID:52;
A24: qz`2= |.q.|* ((q`2/|.q.|-sn)/(1+sn)) by A22,EUCLID:52;
    per cases;
    suppose
A25:  1+sn=0;
      ((q`2/|.q.|-sn)/(1+sn))=(q`2/|.q.|-sn)*(1+sn)" by XCMPLX_0:def 9
        .= (q`2/|.q.|-sn)*0 by A25
        .=0;
      then ((sn-FanMorphW).q)`1=-(|.q.|) & ((sn-FanMorphW).q)`2=0 by A22,
EUCLID:52;
      then |.(sn-FanMorphW).p.|=sqrt((-(|.q.|))^2+0^2) by JGRAPH_3:1
        .=sqrt((|.q.|)^2)
        .=|.q.| by SQUARE_1:22;
      hence thesis;
    end;
    suppose
A26:  1+sn<>0;
      per cases by A26;
      suppose
A27:    1+sn>0;
        then (-(1+sn))/(1+sn)<=(( q`2/|.q.|-sn))/(1+sn) by A21,XREAL_1:72;
        then -1<=(( q`2/|.q.|-sn))/(1+sn) by A27,XCMPLX_1:197;
        then ( (q`2/|.q.|-sn) /(1+sn))^2<=1^2 by A19,A27,SQUARE_1:49;
        then
A28:    1-(((q`2/|.q.|-sn))/(1+sn))^2>=0 by XREAL_1:48;
A29:    (qz`1)^2= (|.q.|)^2*(sqrt(1-((q`2/|.q.|-sn)/(1+sn))^2))^2 by A23
          .= (|.q.|)^2*(1-((q`2/|.q.|-sn)/(1+sn))^2) by A28,SQUARE_1:def 2;
        (|.qz.|)^2=(qz`1)^2+(qz`2)^2 by JGRAPH_3:1
          .=(|.q.|)^2 by A24,A29;
        then sqrt((|.qz.|)^2)=|.q.| by SQUARE_1:22;
        hence thesis by SQUARE_1:22;
      end;
      suppose
A30:    1+sn<0;
        0+(q`2)^2<(q`1)^2+(q`2)^2 by A17,SQUARE_1:12,XREAL_1:8;
        then (q`2)^2/(|.q.|)^2 < (|.q.|)^2/(|.q.|)^2 by A18,A20,XREAL_1:74;
        then (q`2)^2/(|.q.|)^2 < 1 by A18,XCMPLX_1:60;
        then ((q`2)/|.q.|)^2 < 1 by XCMPLX_1:76;
        then -1 < q`2/|.p.| by SQUARE_1:52;
        then
A31:    q`2/|.q.|-sn>-1-sn by XREAL_1:9;
        -(1+sn)>-0 by A30,XREAL_1:24;
        hence thesis by A17,A31,XREAL_1:49;
      end;
    end;
  end;
  suppose
    q`1>=0;
    hence thesis by Th16;
  end;
end;
