reserve f, g, h for Function;
reserve x, y, z, u, X for set,
  A for non empty set,
  n for Element of NAT,
  f for Function of X, X;
reserve f for c=-monotone Function of bool X, bool X,
  S for Subset of X;
reserve X, Y for non empty set,
  f for Function of X, Y,
  g for Function of Y, X;
reserve L for Lattice,
  f for Function of the carrier of L, the carrier of L,
  x for Element of L,
  O, O1, O2, O3, O4 for Ordinal,
  T for Sequence;
reserve L for complete Lattice,
  f for monotone UnOp of L,
  a, b for Element of L;

theorem Th33:
  for a, b st a is_a_fixpoint_of f & b is_a_fixpoint_of f ex O st
card O c= card the carrier of L & (f, O)-.(a"/\"b) is_a_fixpoint_of f & (f, O)
  -.(a"/\"b) [= a & (f, O)-.(a"/\"b) [= b
proof
  let a, b;
  reconsider ab = a"/\"b as Element of L;
A1: ab [= a by LATTICES:6;
  then
A2: f.ab [= f.a by QUANTAL1:def 12;
A3: ab [= b by LATTICES:6;
  then
A4: f.ab [= f.b by QUANTAL1:def 12;
  assume a is_a_fixpoint_of f & b is_a_fixpoint_of f;
  then
A5: a = f.a & b = f.b;
  then consider O such that
A6: card O c= card the carrier of L & (f, O)-.ab is_a_fixpoint_of f by A2,A4
,Th31,FILTER_0:7;
  take O;
  thus card O c= card the carrier of L & (f, O)-.(a"/\"b) is_a_fixpoint_of f
  by A6;
  f.ab [= ab by A5,A2,A4,FILTER_0:7;
  then
A7: (f, O)-.(a"/\"b) [= ab by Th23;
  hence (f, O)-.(a"/\"b) [= a by A1,LATTICES:7;
  thus thesis by A3,A7,LATTICES:7;
end;
