reserve i,j,k,n,l for Element of NAT,
  K for Field,
  a,b,c for Element of K,
  p ,q for FinSequence of K,
  M1,M2,M3 for Matrix of n,K;
reserve D for non empty set,
  t for FinSequence of D,
  A for Matrix of n,D;

theorem Th33:
  p is first-line-of-circulant & q is first-line-of-circulant &
  len p=len q implies p+q is first-line-of-circulant
proof
  set n = len p;
  assume that
A1: p is first-line-of-circulant and
A2: q is first-line-of-circulant and
A3: len p=len q;
  consider M2 being Matrix of n,K such that
A4: M2 is_line_circulant_about q by A2,A3;
A5: dom (p+q)=Seg len (p+q) by FINSEQ_1:def 3;
A6: dom p=Seg n by FINSEQ_1:def 3;
  dom q=Seg n by A3,FINSEQ_1:def 3;
  then
A7: dom (p+q)=dom p by A6,POLYNOM1:1;
  then
A8: len (p+q)=n by A6,FINSEQ_1:def 3;
  consider M1 being Matrix of n,K such that
A9: M1 is_line_circulant_about p by A1;
A10: Indices M1=[:Seg n, Seg n:] by MATRIX_0:24;
  set M3=M1+M2;
A11: width (M1+M2)=n by MATRIX_0:24;
A12: Indices M2=[:Seg n, Seg n:] by MATRIX_0:24;
  for i,j be Nat st [i,j] in Indices M3 holds M3*(i,j)=(p+q).((j-i mod len
  (p+q))+1)
  proof
    let i,j be Nat;
    assume
A13: [i,j] in Indices (M1+M2);
    then
A14: [i,j] in Indices M1 by A10,MATRIX_0:24;
    then
A15: (j-i mod len (p+q))+1 in dom (p+q) by A10,A6,A5,A7,Lm3;
A16: [i,j] in Indices M2 by A12,A13,MATRIX_0:24;
    M3*(i,j) =M1*(i,j)+M2*(i,j) by A14,MATRIX_3:def 3
      .=(the addF of K).(M1*(i,j),q.((j-i mod len q)+1)) by A4,A16
      .=(the addF of K).(p.((j-i mod len (p+q))+1),q.((j-i mod len (p+q))+1)
    ) by A3,A9,A8,A14
      .=(p+q).((j-i mod len (p+q))+1) by A15,FUNCOP_1:22;
    hence thesis;
  end;
  then M1+M2 is_line_circulant_about (p+q) by A11,A8;
  then consider M3 being Matrix of len (p+q),K such that
  len (p+q)=width M3 and
A17: M3 is_line_circulant_about p+q by A11;
  take M3;
  thus thesis by A17;
end;
