reserve v,x for object;
reserve D,V,A for set;
reserve n for Nat;
reserve p,q for PartialPredicate of D;
reserve f,g for BinominativeFunction of D;
reserve D for non empty set;
reserve d for Element of D;
reserve f,g for BinominativeFunction of D;
reserve p,q,r,s for PartialPredicate of D;
reserve p,q for SCPartialNominativePredicate of V,A;
reserve f,g for SCBinominativeFunction of V,A;
reserve E for (V,A)-FPrg-yielding FinSequence;
reserve e for Element of product E;
reserve d for TypeSCNominativeData of V,A;

theorem
  product E <> {} &
  <*p, PP_composition(SC_Fsuperpos(PPid(ND(V,A)),e,E),f), q*>
    is SFHT of ND(V,A)
  implies
  <*p,SC_Fsuperpos(f,e,E),q*> is SFHT of ND(V,A)
  proof
    assume
A1: product E <> {};
    set I = PPid(ND(V,A));
    set F = SC_Fsuperpos(f,e,E);
    set G = SC_Fsuperpos(I,e,E);
    set C = PP_composition(G,f);
    assume <*p,C,q*> is SFHT of ND(V,A);
    then
A2: for d holds d in dom p & p.d = TRUE & d in dom C & C.d in dom q
     implies q.(C.d) = TRUE by Th11;
    for d holds d in dom p & p.d = TRUE & d in dom F & F.d in dom q implies
     q.(F.d) = TRUE
    proof
      let d such that
A3:   d in dom p and
A4:   p.d = TRUE and
A5:   d in dom F and
A6:   F.d in dom q;
      set X = E;
      set o = global_overlapping(V,A,d,NDentry(E,X,d));
A7:   o in ND(V,A);
      F = SCFsuperpos(E,X).(f,e) by A1,NOMIN_2:def 14;
      then dom F = {d where d is TypeSCNominativeData of V,A:
       global_overlapping(V,A,d,NDentry(E,X,d)) in dom f & d in_doms E}
        by A1,NOMIN_2:def 13;
      then consider d1 being TypeSCNominativeData of V,A such that
A8:   d = d1 and
A9:   global_overlapping(V,A,d1,NDentry(E,X,d1)) in dom f and
A10:  d1 in_doms E by A5;
      G = SCFsuperpos(E,X).(I,e) by A1,NOMIN_2:def 14;
      then dom G = {d where d is TypeSCNominativeData of V,A:
       global_overlapping(V,A,d,NDentry(E,X,d)) in dom I & d in_doms E}
        by A1,NOMIN_2:def 13;
      then
A11:  d in dom G by A7,A8,A10;
A12:  F.d = f.o by A1,A5,NOMIN_2:37;
A13:  o = I.o by A7,FUNCT_1:18
      .= G.d by A1,A11,NOMIN_2:37;
A14:  C = f*G by PARTPR_2:def 1;
      then C.d = f.(G.d) by A11,FUNCT_1:13;
      hence q.(F.d) = TRUE by A2,A3,A4,A6,A12,A11,A14,A8,A9,A13,FUNCT_1:11;
    end;
    hence thesis by Th27;
  end;
