reserve S for OrderSortedSign;
reserve S for OrderSortedSign,
  X for ManySortedSet of S,
  o for OperSymbol of S ,
  b for Element of ([:the carrier' of S,{the carrier of S}:] \/ Union (coprod X
  ))*;
reserve x for set;

theorem Th33:
  for S be locally_directed OrderSortedSign, X be non-empty
ManySortedSet of S, s be Element of S, t being Element of TS DTConOSA(X), x,x1
being set st x in X.s & t = root-tree [x,s] holds x1 in OSClass(PTCongruence(X)
  ,t) iff x1 = t
proof
  let S be locally_directed OrderSortedSign, X be non-empty ManySortedSet of S
  , s be Element of S, t being Element of TS DTConOSA(X);
  set PTA = ParsedTermsOSA(X), D = DTConOSA(X),R= PTCongruence(X);
  reconsider y = t as Element of (the Sorts of PTA).(LeastSort t) by Def12;
  let x,x1 being set such that
A1: x in X.s and
A2: t = root-tree [x,s];
A3: [x,s] in Terminals D by A1,Th4;
  then reconsider sy = [x,s] as Symbol of D;
A4: OSClass(R,t) = OSClass(PTCongruence X,y) by Def27
    .= proj1((PTClasses X).y) by Th25;
A5: (PTClasses X).(root-tree sy) = @(sy) by A3,Def21
    .= {[root-tree sy,s1] where s1 is Element of S: ex s2 be Element of S,
  x2 be set st x2 in X.s2 & sy = [x2,s2] & s2 <= s1};
  hereby
    assume x1 in OSClass(R,t);
    then consider z being object such that
A6: [x1,z] in (PTClasses X).y by A4,XTUPLE_0:def 12;
    ex s1 being Element of S st [x1,z] = [root-tree sy,s1] & ex s2 be
Element of S, x2 be set st x2 in X.s2 & sy = [x2,s2] & s2 <= s1 by A2,A5,A6;
    hence x1 = t by A2,XTUPLE_0:1;
  end;
  assume x1 = t;
  then [x1,s] in (PTClasses X).y by A1,A2,A5;
  hence thesis by A4,XTUPLE_0:def 12;
end;
