reserve n,m,k for Element of NAT,
  x,X for set,
  A1 for SetSequence of X,
  Si for SigmaField of X,
  XSeq for SetSequence of Si;
reserve Omega for non empty set,
  Sigma for SigmaField of Omega,
  ASeq for SetSequence of Sigma,
  P for Probability of Sigma;

theorem Th33:
  for BSeq being SetSequence of Omega st (for n holds BSeq.n is
  thin of P) holds ex CSeq being SetSequence of Sigma st for n holds BSeq.n c=
  CSeq.n & P.(CSeq.n) = 0
proof
  let BSeq be SetSequence of Omega;
  defpred P[Element of NAT, set] means for n being Element of NAT for y being
  set holds (n = $1 & y = $2 implies y in Sigma & BSeq.n c= y & P.y = 0);
  assume
A1: for n holds BSeq.n is thin of P;
A2: for t being Element of NAT ex A being Element of Sigma st P[t,A]
  proof
    let t be Element of NAT;
    BSeq.t is thin of P by A1;
    then consider A being set such that
A3: A in Sigma and
A4: BSeq.t c= A & P.A = 0 by Def4;
    reconsider A as Element of Sigma by A3;
    take A;
    thus thesis by A4;
  end;
  ex G being sequence of Sigma st for t being Element of NAT holds P[t
  ,G.t] from FUNCT_2:sch 3(A2);
  then consider G being sequence of Sigma such that
A5: for t being Element of NAT holds for n being Element of NAT for y
  being set holds (n = t & y = G.t implies y in Sigma & BSeq.n c= y & P.y = 0);
  reconsider CSeq = G as SetSequence of Omega by FUNCT_2:7;
  reconsider CSeq as SetSequence of Sigma;
  take CSeq;
  thus thesis by A5;
end;
