reserve x,y,y1,y2 for set,
  p for FinSequence,
  i,k,l,n for Nat,
  V for RealLinearSpace,
  u,v,v1,v2,v3,w for VECTOR of V,
  a,b for Real,
  F,G,H1,H2 for FinSequence of V,
  A,B for Subset of V,
  f for Function of the carrier of V, REAL;
reserve K,L,L1,L2,L3 for Linear_Combination of V;
reserve l,l1,l2 for Linear_Combination of A;

theorem Th33:
  v1 <> v2 implies for l being Linear_Combination of {v1,v2} holds
  Sum(l) = l.v1 * v1 + l.v2 * v2
proof
  assume
A1: v1 <> v2;
  let l be Linear_Combination of {v1,v2};
A2: Carrier(l) c= {v1,v2} by Def6;
  now
    per cases by A2,ZFMISC_1:36;
    suppose
      Carrier(l) = {};
      then
A3:   l = ZeroLC(V) by Def5;
      hence Sum(l) = 0.V by Lm2
        .= 0.V + 0.V
        .= 0 * v1 + 0.V by RLVECT_1:10
        .= 0 * v1 + 0 * v2 by RLVECT_1:10
        .= l.v1 * v1 + 0 * v2 by A3,Th20
        .= l.v1 * v1 + l.v2 * v2 by A3,Th20;
    end;
    suppose
A4:   Carrier(l) = {v1};
      then reconsider L = l as Linear_Combination of {v1} by Def6;
A5:   not v2 in Carrier(l) by A1,A4,TARSKI:def 1;
      thus Sum(l) = Sum(L) .= l.v1 * v1 by Th32
        .= l.v1 * v1 + 0.V
        .= l.v1 * v1 + 0 * v2 by RLVECT_1:10
        .= l.v1 * v1 + l.v2 * v2 by A5;
    end;
    suppose
A6:   Carrier(l) = {v2};
      then reconsider L = l as Linear_Combination of {v2} by Def6;
A7:   not v1 in Carrier(l) by A1,A6,TARSKI:def 1;
      thus Sum(l) = Sum(L) .= l.v2 * v2 by Th32
        .= 0.V + l.v2 * v2
        .= 0 * v1 + l.v2 * v2 by RLVECT_1:10
        .= l.v1 * v1 + l.v2 * v2 by A7;
    end;
    suppose
      Carrier(l) = {v1,v2};
      then consider F such that
A8:   F is one-to-one & rng F = {v1,v2} and
A9:   Sum(l) = Sum(l (#) F) by Def8;
      F = <* v1,v2 *> or F = <* v2,v1 *> by A1,A8,FINSEQ_3:99;
      then l (#) F = <* l.v1 * v1, l.v2 * v2 *> or l (#) F = <* l.v2 * v2, l.
      v1 * v1 *> by Th27;
      hence thesis by A9,RLVECT_1:45;
    end;
  end;
  hence thesis;
end;
