reserve L for Ortholattice,
  a, b, c for Element of L;

theorem
  L is orthomodular iff for a,b being Element of L st a _|_ b & a "\/" b
  = Top L holds a = b`
proof
  thus L is orthomodular implies for a,b being Element of L st a _|_ b & a
  "\/" b = Top L holds a = b`
  proof
    assume
A1: L is orthomodular;
    let x,y be Element of L;
    assume x _|_ y;
    then
A2: x [= y`;
    assume
A3: x "\/" y = Top L;
    thus y` = x "\/" (x` "/\" y`) by A1,A2
      .= x "\/" (x`` "\/" y``)` by ROBBINS1:def 23
      .= x "\/" (x "\/" y``)` by ROBBINS3:def 6
      .= x "\/" (x "\/" y)` by ROBBINS3:def 6
      .= x "\/" (x``"\/"x`)` by A3,Th2
      .= x "\/" (x`"/\"x) by ROBBINS1:def 23
      .= x by LATTICES:def 8;
  end;
  assume
A4: for a,b being Element of L st a _|_ b & a "\/" b = Top L holds a = b `;
  let x,y be Element of L;
  assume x [= y;
  then x "\/" (x` "/\" y) [= y "\/" (x` "/\" y) by FILTER_0:1;
  then x "\/" (x` "/\" y) [= y by LATTICES:def 8;
  then x "\/" (x` "/\" y) [= y`` by ROBBINS3:def 6;
  then
A5: x "\/" (x` "/\" y) _|_ y`;
  y` "\/" (x "\/" (x` "/\" y)) = (y` "\/" x) "\/" (x` "/\" y) by LATTICES:def 5
    .= (y` "\/" x``) "\/" (x` "/\" y) by ROBBINS3:def 6
    .= (y` "\/" x``)`` "\/" (x` "/\" y) by ROBBINS3:def 6
    .= (y "/\" x`)` "\/" (x` "/\" y) by ROBBINS1:def 23
    .= Top L by Th2;
  then x "\/" (x` "/\" y) = y`` by A4,A5;
  hence thesis by ROBBINS3:def 6;
end;
