reserve x,x0, r,r1,r2 for Real,
      th for Real,

  rr for set,

  rseq for Real_Sequence;

theorem Th33:
  for x be set st x in [.0,PI/4.] holds sec.x in [.1,sqrt 2.]
proof
  let x be set;
  assume x in [.0,PI/4.];
  then x in ].0,PI/4.[ \/ {0,PI/4} by XXREAL_1:128;
  then
A1: x in ].0,PI/4.[ or x in {0,PI/4} by XBOOLE_0:def 3;
  per cases by A1,TARSKI:def 2;
  suppose
A2: x in ].0,PI/4.[;
    PI/4 < PI/2 by XREAL_1:76;
    then 0 in [.0,PI/2.[ & PI/4 in [.0,PI/2.[;
    then
A3: [.0,PI/4.] c= [.0,PI/2.[ by XXREAL_2:def 12;
    then
A4: sec|[.0,PI/4.] is increasing by Th17,RFUNCT_2:28;
A5: ex s be Real st s=x & 0 < s & s < PI/4 by A2;
A6: ].0,PI/4.[ c= [.0,PI/4.] by XXREAL_1:25;
A7: [.0,PI/4.] /\ dom sec = [.0,PI/4.] by A3,Th1,XBOOLE_1:1,28;
    0 in [.0,PI/4.] & ex s be Real st s=x & 0 < s & s < PI/4 by A2;
    then
A8: 1 < sec.x by A2,A4,A7,A6,Th31,RFUNCT_2:20;
    PI/4 in [.0,PI/4.] /\ dom sec by A7;
    then sec.x < sqrt 2 by A2,A4,A7,A6,A5,Th31,RFUNCT_2:20;
    hence thesis by A8;
  end;
  suppose
    x = 0;
    hence thesis by Th31,SQUARE_1:19;
  end;
  suppose
    x = PI/4;
    hence thesis by Th31,SQUARE_1:19;
  end;
end;
