reserve T,T1,T2 for TopSpace,
  A,B for Subset of T,
  F for Subset of T|A,
  G,G1, G2 for Subset-Family of T,
  U,W for open Subset of T|A,
  p for Point of T|A,
  n for Nat,
  I for Integer;
reserve Af for finite-ind Subset of T,
  Tf for finite-ind TopSpace;

theorem Th33:
  for X be set,f be SetSequence of X ex g be SetSequence of X st
union rng f = union rng g & (for i,j be Nat st i<>j holds g.i misses g.j) & for
n ex fn be finite Subset-Family of X st fn={f.i where i is Element of NAT:i<n}
  & g.n=f.n \ union fn
proof
  let X be set,f be SetSequence of X;
  defpred P[object,object] means
   for n st n=$1ex fn be finite Subset-Family of X st
  fn={f.i where i is Element of NAT:i<n} & $2=f.n\union fn;
A1: for x be object st x in NAT ex y be object st y in bool X & P[x,y]
  proof
    let x be object;
    assume x in NAT;
    then reconsider n=x as Element of NAT;
    deffunc F(Nat)=f.$1;
    set fn={F(i) where i is Element of NAT:i in n};
A2: fn c=bool X
    proof
      let z be object;
      assume z in fn;
      then ex i be Element of NAT st z=F(i) & i in n;
      hence thesis;
    end;
A3: n is finite;
    fn is finite from FRAENKEL:sch 21(A3);
    then reconsider fn as finite Subset-Family of X by A2;
    take y=f.n\union fn;
    thus y in bool X;
    let m be Nat such that
A4: m=x;
    set Fn={f.i where i is Element of NAT:i<n};
    take fn;
A5: fn c=Fn
    proof
      let z be object;
      assume z in fn;
      then consider i be Element of NAT such that
A6:   z=f.i and
A7:   i in Segm n;
      i<n by A7,NAT_1:44;
      hence thesis by A6;
    end;
    Fn c=fn
    proof
      let z be object;
      assume z in Fn;
      then consider i be Element of NAT such that
A8:   z=f.i and
A9:   i<n;
      i in Segm n by A9,NAT_1:44;
      hence thesis by A8;
    end;
    hence thesis by A4,A5;
  end;
  consider g be SetSequence of X such that
A10: for x be object st x in NAT holds P[x,g.x] from FUNCT_2:sch 1(A1);
  take g;
A11: union rng f c=union rng g
  proof
    let y be object;
    defpred Q[Nat] means y in f.$1;
    assume y in union rng f;
    then consider Y be set such that
A12: y in Y and
A13: Y in rng f by TARSKI:def 4;
    ex x be object st x in dom f & f.x=Y by A13,FUNCT_1:def 3;
    then
A14: ex n st Q[n] by A12;
    consider Min be Nat such that
A15: Q[Min] and
A16: for n st Q[n] holds Min<=n from NAT_1:sch 5(A14);
A17: Min in NAT by ORDINAL1:def 12;
    then consider fn be finite Subset-Family of X such that
A18: fn={f.i where i is Element of NAT:i<Min} and
A19: g.Min=f.Min\union fn by A10;
    not y in union fn
    proof
      assume y in union fn;
      then consider Z be set such that
A20:  y in Z and
A21:  Z in fn by TARSKI:def 4;
      ex i be Element of NAT st Z=f.i & i<Min by A18,A21;
      hence thesis by A16,A20;
    end;
    then
A22: y in g.Min by A15,A19,XBOOLE_0:def 5;
    dom g=NAT by FUNCT_2:def 1;
    then g.Min in rng g by A17,FUNCT_1:def 3;
    hence thesis by A22,TARSKI:def 4;
  end;
  union rng g c=union rng f
  proof
    let y be object;
    assume y in union rng g;
    then consider Y be set such that
A23: y in Y and
A24: Y in rng g by TARSKI:def 4;
    consider x be object such that
A25: x in dom g and
A26: g.x=Y by A24,FUNCT_1:def 3;
    reconsider n=x as Nat by A25;
    ex fn be finite Subset-Family of X st fn={f.i where i is Element of
    NAT:i<n} & g.n=f.n\union fn by A10,A25;
    then
A27: y in f.n by A23,A26,XBOOLE_0:def 5;
    dom f=NAT by FUNCT_2:def 1;
    then f.n in rng f by A25,FUNCT_1:def 3;
    hence thesis by A27,TARSKI:def 4;
  end;
  hence union rng f=union rng g by A11;
A28: for i,j be Nat st i<j holds g.i misses g.j
  proof
    let i,j be Nat such that
A29: i<j;
    j in NAT by ORDINAL1:def 12;
    then consider fj be finite Subset-Family of X such that
A30: fj={f.n where n is Element of NAT:n<j} and
A31: g.j=f.j\union fj by A10;
    assume g.i meets g.j;
    then consider x be object such that
A32: x in g.i and
A33: x in g.j by XBOOLE_0:3;
A34: i in NAT by ORDINAL1:def 12;
    then ex fi be finite Subset-Family of X st fi={f.n where n is Element of
    NAT:n<i} & g.i=f.i\union fi by A10;
    then
A35: x in f.i by A32,XBOOLE_0:def 5;
    f.i in fj by A29,A30,A34;
    then x in union fj by A35,TARSKI:def 4;
    hence contradiction by A31,A33,XBOOLE_0:def 5;
  end;
  thus for i,j be Nat st i<>j holds g.i misses g.j
  proof
    let i,j be Nat;
    assume i<>j;
    then i<j or j<i by XXREAL_0:1;
    hence thesis by A28;
  end;
  let n;
  n in NAT by ORDINAL1:def 12;
  hence thesis by A10;
end;
