reserve
  X for non empty set,
  FX for Filter of X,
  SFX for Subset-Family of X;

theorem Th12:
  for X,Y be non empty set,f be Function of X,Y,
  F be Filter of X, B be basis of F holds
  f.:( #B ) is filter_base of Y &
  <.(f.:( #B )).] is Filter of Y &
  <.(f.:( #B )).] = { M where M is Subset of Y: f"(M) in F}
  proof
    let X,Y be non empty set,f be Function of X,Y,
    F be Filter of X,B be basis of F;
    set FB=f.:( #B );
    now
      set b0 = the Element of B;
      f.:b0 in FB by FUNCT_2:def 10;
      hence FB is non empty;
    end;
    then reconsider FB1=FB as non empty Subset-Family of Y;
A1: FB is quasi_basis non empty Subset-Family of Y
    proof
      now
        let b1,b2 be Element of FB;
        b1 in FB1;
        then consider M be Subset of X such that
A2:     M in #B and
A3:     b1=f.:M by FUNCT_2:def 10;
        b2 in FB1;
        then
        consider N be Subset of X such that
A4:     N in #B and
A5:     b2=f.:N by FUNCT_2:def 10;
        #B is quasi_basis & M in #B & N in #B by A2,A4,Th09;
        then consider P be Element of B such that
A6:     P c= M/\N;
A7:     f.:P c= f.:(M /\ N) by A6,RELAT_1:123;
        f.:(M /\ N) c=f.:M /\ f.:N by RELAT_1:121;
        then
A8:     f.:P c= b1 /\ b2 by A3,A5,A7;
        f.:P is Element of FB by FUNCT_2:def 10;
        hence ex b be Element of FB st b c= b1/\b2 by A8;
      end;
      then FB1 is quasi_basis;
      hence thesis;
    end;
A9: FB is with_non-empty_elements
    proof
      assume not FB is with_non-empty_elements;
      then consider x be Subset of X such that
A10:  x in #B and
A11:  {} = f.:x by FUNCT_2:def 10;
      dom f = X by FUNCT_2:def 1;
      then X misses x by A11,RELAT_1:118;
      then {} in B by A10,XBOOLE_1:67;
      hence contradiction by CARD_FIL:def 1;
    end;
    hence FB is filter_base of Y by A1;
    thus <.FB.] is Filter of Y by A1,A9,Th08;
    thus <.FB.] = { M where M is Subset of Y: f"(M) in F}
    proof
      hereby
        let y be object;
        assume
A12:    y in <.FB.];
        then reconsider y0=y as Subset of Y;
        consider b be Element of FB such that
A13:    b c= y0 by A12,def3;
        b in FB1;
        then
        consider M be Subset of X such that
A14:    M in #B and
A15:    b=f.:M by FUNCT_2:def 10;
A16:    f"(f.:M) c= f"(y0) by A13,A15,RELAT_1:143;
        M c= f"(f.:M) by FUNCT_2:42;
        then M c= f"(y0) by A16;
        then f"(y0) in <.#B.] by A14,def3;
        then f"(y0) in F by Th06;
        hence y in { M where M is Subset of Y: f"(M) in F};
      end;
      let x be object;
      assume x in { M where M is Subset of Y: f"(M) in F};
      then consider M0 be Subset of Y such that
A17:  x=M0 and
A18:  f"(M0) in F;
      f"(M0) in <.#B.] by A18,Th06;
      then consider b0 be Element of #B such that
A19:  b0 c= f"(M0) by def3;
A20:  f.:b0 c= f.:(f"(M0)) by A19,RELAT_1:123;
      reconsider fb=f.:b0 as Element of FB by FUNCT_2:def 10;
      f.:(f"(M0)) c= M0 by FUNCT_1:75;
      then fb c= M0 by A20;
      hence x in <.FB.] by A17,def3;
    end;
  end;
