reserve i,n,m for Nat,
  x,y,X,Y for set,
  r,s for Real;

theorem Th33:
  for T be non empty TopSpace holds T is second-countable implies
  for F being Subset-Family of T st F is Cover of T & F is open ex G being
  Subset-Family of T st G c= F & G is Cover of T & G is countable
proof
  let T be non empty TopSpace;
  assume T is second-countable;
  then consider B being Basis of T such that
A1: B is countable by TOPGEN_4:57;
A2: card B c= omega by A1,CARD_3:def 14;
  let F being Subset-Family of T such that
A3: F is Cover of T and
A4: F is open;
  defpred P[object,object] means
   ex D2 being set st D2 = $2 &
for b be Subset of T st b=$1 holds ((ex y st y in F
  & b c= y) implies ($2 in F & b c= D2)) & ((for y st y in F holds not b c= y)
  implies $2={});
A5: for x being object st x in B
ex y being object st y in bool(the carrier of T) & P[x,y]
  proof
    let x be object;
    assume x in B;
    then reconsider b=x as Subset of T;
    per cases;
    suppose
      ex y st y in F & b c= y;
      then consider y such that
A6:   y in F and
A7:   b c= y;
      reconsider y as Subset of T by A6;
      take y;
      thus y in bool the carrier of T;
      take y;
      thus thesis by A6,A7;
    end;
    suppose
A8:   for y st y in F holds not b c= y;
      take y={}T;
      thus y in bool the carrier of T;
      take y;
      thus thesis by A8;
    end;
  end;
  consider p be Function of B,bool(the carrier of T) such that
A9: for x being object st x in B holds P[x,p.x] from FUNCT_2:sch 1(A5);
  take RNG=rng p\{{}};
A10: dom p=B by FUNCT_2:def 1;
  thus RNG c= F
  proof
    let y be object such that
A11: y in RNG;
    y in rng p by A11,XBOOLE_0:def 5;
    then consider z be object such that
A12: z in dom p and
A13: p.z=y by FUNCT_1:def 3;
    reconsider z as Subset of T by A10,A12;
A14: P[z,p.z] by A9,A12;
     (ex y st y in F & z c= y) or for y st y in F holds not z c= y;
    then p.z in F & z c= p.z or p.z={} by A14;
    hence thesis by A11,A13,ZFMISC_1:56;
  end;
  the carrier of T c= union RNG
  proof
    let y be object;
    assume y in the carrier of T;
    then reconsider q=y as Point of T;
    consider W be Subset of T such that
A15: q in W and
A16: W in F by A3,PCOMPS_1:3;
    W is open by A4,A16;
    then consider U be Subset of T such that
A17: U in B and
A18: q in U and
A19: U c= W by A15,YELLOW_9:31;
A20: p.U in rng p by A10,A17,FUNCT_1:def 3;
    then reconsider pU=p.U as Subset of T;
    P[U,p.U] by A9,A17;
    then
A21: U c= pU by A16,A19;
    then pU in RNG by A18,A20,ZFMISC_1:56;
    hence thesis by A18,A21,TARSKI:def 4;
  end;
  then [#]T=union RNG by XBOOLE_0:def 10;
  hence RNG is Cover of T by SETFAM_1:45;
  card rng p c= card B by A10,CARD_2:61;
  then card rng p c= omega by A2;
  then rng p is countable by CARD_3:def 14;
  hence thesis by CARD_3:95;
end;
