reserve x,X,X2,Y,Y2 for set;
reserve GX for non empty TopSpace;
reserve A2,B2 for Subset of GX;
reserve B for Subset of GX;

theorem
  for T being non empty TopSpace for A being non empty
  a_union_of_components of T st A is connected holds A is a_component
proof
  let T be non empty TopSpace;
  let A be non empty a_union_of_components of T;
  consider F being Subset-Family of T such that
A1: for B being Subset of T st B in F holds B is a_component and
A2: A = union F by Def2;
  consider X being set such that
  X <> {} and
A3: X in F by A2,ORDERS_1:6;
  reconsider X as Subset of T by A3;
  assume
A4: A is connected;
  F={X}
  proof
    thus F c= {X}
    proof
      let x be object;
      assume
A5:   x in F;
      then reconsider Y=x as Subset of T;
A6:   X is a_component & X c= A by A1,A2,A3,ZFMISC_1:74;
      Y is a_component & Y c= A by A1,A2,A5,ZFMISC_1:74;
      then Y = A by A4,CONNSP_1:def 5
        .= X by A4,A6,CONNSP_1:def 5;
      hence thesis by TARSKI:def 1;
    end;
    let x be object;
    assume x in {X};
    hence thesis by A3,TARSKI:def 1;
  end;
  then A = X by A2,ZFMISC_1:25;
  hence thesis by A1,A3;
end;
