
theorem :: Corollary 4.43
  for R being non empty Poset, N being non empty Subset of R st R is Dickson
  holds ex B being set st B is_Dickson-basis_of N, R &
  for C being set st C is_Dickson-basis_of N, R holds B c= C
proof
  let R be non empty Poset, N be non empty Subset of R such that
A1: R is Dickson;
  set IR=the InternalRel of R, CR = the carrier of R;
  set IR9=the InternalRel of R\~;
  set B = {b where b is Element of R\~ : b is_minimal_wrt N, IR9};
A2: R is quasi_ordered;
  for f being sequence of R ex i,j being Nat
  st i < j & f.i <= f.j by A1,Th28;
  then min-classes N is non empty by A2,Th30;
  then consider x being object such that
A3: x in min-classes N by XBOOLE_0:def 1;
  consider y being Element of R\~ such that
A4: y is_minimal_wrt N, IR9 and x = Class(EqRel R, y) /\ N by A3,Def8;
  y in B by A4;
  then reconsider B as non empty set;
  take B;
A5: now
    let x be object;
    assume x in B;
    then ex b being Element of R\~ st ( x = b)&( b is_minimal_wrt N, IR9);
    hence x in N by WAYBEL_4:def 25;
  end;
  then
A6: B c= N;
  thus B is_Dickson-basis_of N, R
  proof
    thus B c= N by A5;
    let a be Element of R such that
A7: a in N;
    reconsider a9=a as Element of R\~;
    now
      assume
A8:   not ex b being Element of R st b in B & b <= a;
      per cases;
      suppose IR9-Seg(a) /\ N = {};
        then IR9-Seg(a) misses N by XBOOLE_0:def 7;
        then a9 is_minimal_wrt N, IR9 by A7,Th5;
        then a in B;
        hence contradiction by A8;
      end;
      suppose
A9:     IR9-Seg(a) /\ N <> {};
        R\~ is well_founded by A1,A2,Th32;
        then IR9 is_well_founded_in CR by WELLFND1:def 2;
        then consider z being object such that
A10:    z in IR9-Seg(a) /\ N and
A11:    IR9-Seg(z) misses (IR9-Seg(a) /\ N) by A9,WELLORD1:def 3;
A12:    z in IR9-Seg(a) by A10,XBOOLE_0:def 4;
        then [z,a] in IR9 by WELLORD1:1;
        then z in dom IR9 by XTUPLE_0:def 12;
        then reconsider z as Element of R\~;
        reconsider z9 = z as Element of R;
        z is_minimal_wrt IR9-Seg(a9) /\ N, IR9 by A10,A11,Th5;
        then z is_minimal_wrt N, IR9 by Th6;
        then
A13:    z in B;
        [z,a] in IR \ IR~ by A12,WELLORD1:1;
        then z9 <= a;
        hence contradiction by A8,A13;
      end;
    end;
    hence ex b being Element of R st b in B & b <= a;
  end;
  let C be set such that
A14: C is_Dickson-basis_of N, R;
A15: C c= N by A14;
  now
    let b be object such that
A16: b in B;
    b in N by A5,A16;
    then reconsider b9=b as Element of R;
    consider c being Element of R such that
A17: c in C and
A18: c <= b9 by A6,A14,A16;
A19: ex b99 being Element of R\~ st ( b99 = b)&( b99
    is_minimal_wrt N, IR9) by A16;
A20: [c,b] in IR by A18;
A21: IR is_antisymmetric_in CR by ORDERS_2:def 4;
    [b,c] in IR by A15,A17,A19,A20,Th16;
    hence b in C by A17,A18,A21;
  end;
  hence thesis;
end;
