reserve x for set;
reserve i,j for Integer;
reserve n,n1,n2,n3 for Nat;
reserve p for Prime;
reserve a,b,c,d for Element of GF(p);
reserve K for Ring;
reserve a1,a2,a3,a4,a5,a6 for Element of K;
reserve px,py,pz for object;
reserve Px,Py,Pz for Element of GF(p);
reserve P for Element of ProjCo(GF(p));
reserve O for Element of EC_SetProjCo(a,b,p);

theorem Th34:
  P is_on_curve EC_WEqProjCo(a,b,p) iff P is Element of EC_SetProjCo(a,b,p)
  proof
    hereby assume P is_on_curve EC_WEqProjCo(a,b,p);
      then P in {Q where Q is Element of ProjCo(GF(p)) :
      EC_WEqProjCo(a,b,p).Q = 0.GF(p)};
      hence P is Element of EC_SetProjCo(a,b,p) by EC_PF_1:def 9;
    end;
    assume P is Element of EC_SetProjCo(a,b,p);
    then P in EC_SetProjCo(a,b,p);
    then P in {Q where Q is Element of ProjCo(GF(p)) :
    EC_WEqProjCo(a,b,p).Q = 0.GF(p)} by EC_PF_1:def 9;
    then ex Q be Element of ProjCo(GF(p)) st P=Q &
    EC_WEqProjCo(a,b,p).Q = 0.GF(p);
    hence P is_on_curve EC_WEqProjCo(a,b,p);
  end;
