reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem Th34:
  for M being Matrix of D for p being FinSequence of D* st len p =
len M & p.1 = M.1 & (for k st k >= 1 & k < len M holds p.(k+1) = (p.k) ^ M.(k+1
)) holds for j st j >= 1 & j < len p holds for l st l in Seg width M holds (j*
  width M+l) in dom (p.(j+1)) & (p.(j+1)).(j*width M+l)=(M.(j+1)).l
proof
  let M be Matrix of D;
  let p be FinSequence of D* such that
A1: len p = len M and
A2: p.1 = M.1 and
A3: for k st k >= 1 & k < len M holds p.(k+1) = (p.k) ^ M.(k+1);
  let j such that
A4: j >= 1 and
A5: j < len p;
A6: j+1 >=1 by A4,NAT_1:13;
  j in Seg len p by A4,A5,FINSEQ_1:1;
  then j in dom p by FINSEQ_1:def 3;
  then
A7: len(p.j) = j * width M by A1,A2,A3,Th29;
  let l such that
A8: l in Seg width M;
A9: l <= width M by A8,FINSEQ_1:1;
  j+1 <= len M by A1,A5,NAT_1:13;
  then j+1 in Seg len M by A6,FINSEQ_1:1;
  then
A10: j+1 in dom M by FINSEQ_1:def 3;
  then
A11: l in dom(M.(j+1)) by A8,Th18;
  l >= 1 by A8,FINSEQ_1:1;
  then
A12: j*width M + l >= 0+1 by XREAL_1:7;
  dom p = dom M by A1,FINSEQ_3:29;
  then len(p.(j+1)) = (j+1) * width M by A1,A2,A3,A10,Th29
    .= j * width M + width M;
  then j*width M + l <= len(p.(j+1)) by A9,XREAL_1:7;
  then j*width M + l in Seg len(p.(j+1)) by A12,FINSEQ_1:1;
  hence j*width M + l in dom(p.(j+1)) by FINSEQ_1:def 3;
  p.(j+1) = (p.j) ^ M.(j+1) by A1,A3,A4,A5;
  hence thesis by A11,A7,FINSEQ_1:def 7;
end;
