reserve FT for non empty RelStr,
  A,B,C for Subset of FT;

theorem Th33:
  for A,B being Subset of FT st FT is symmetric & A is connected &
  B is connected & not A,B are_separated holds A \/ B is connected
proof
  let A,B be Subset of FT;
  assume that
A1: FT is symmetric and
A2: A is connected and
A3: B is connected and
A4: not A,B are_separated;
  given P,Q being Subset of FT such that
A5: A \/ B = P \/ Q and
A6: P <> {} and
A7: Q <> {} and
A8: P misses Q and
A9: P^b misses Q;
  set P2=A/\P,Q2=A/\Q;
A10: P2 misses Q2 by A8,XBOOLE_1:76;
A11: Q^b misses P by A1,A9,Th5;
A12: now
    assume that
A13: A c= Q and
A14: B c= P;
    per cases by A4,FINTOPO4:def 1;
    suppose
      A^b meets B;
      then Q^b meets B by A13,FIN_TOPO:14,XBOOLE_1:63;
      hence contradiction by A11,A14,XBOOLE_1:63;
    end;
    suppose
      A meets (B^b);
      then not A^b misses B by A1,Th5;
      then Q^b meets B by A13,FIN_TOPO:14,XBOOLE_1:63;
      hence contradiction by A11,A14,XBOOLE_1:63;
    end;
  end;
A15: now
    assume
A16: A/\P={};
    then
A17: A/\Q=A/\P \/ A/\Q .=A/\(P\/Q) by XBOOLE_1:23
      .=A by A5,XBOOLE_1:21;
A18: now
      assume B/\Q={};
      then B/\P=B/\Q \/ B/\P .=B/\(Q\/P) by XBOOLE_1:23
        .=B by A5,XBOOLE_1:21;
      hence contradiction by A12,A17,XBOOLE_1:18;
    end;
    set P3=B/\P,Q3=B/\Q;
A19: P3\/Q3=B/\(P\/Q) by XBOOLE_1:23
      .=B by A5,XBOOLE_1:21;
A20: P3 misses Q3 by A8,XBOOLE_1:76;
    P3^b c= P^b & Q3 c= Q by FIN_TOPO:14,XBOOLE_1:17;
    then
A21: P3^b misses Q3 by A9,XBOOLE_1:64;
    B/\P=A/\P \/ B/\P by A16
      .=(A\/B)/\P by XBOOLE_1:23
      .=P by A5,XBOOLE_1:21;
    hence contradiction by A3,A6,A18,A19,A20,A21;
  end;
A22: now
    assume that
A23: A c= P and
A24: B c= Q;
A25: A^b c= P^b by A23,FIN_TOPO:14;
    per cases by A4,FINTOPO4:def 1;
    suppose
      A^b meets B;
      hence contradiction by A9,A24,A25,XBOOLE_1:64;
    end;
    suppose
      A meets (B^b);
      then not A^b misses B by A1,Th5;
      hence contradiction by A9,A24,A25,XBOOLE_1:64;
    end;
  end;
A26: now
    assume
A27: A/\Q={};
    then
A28: A/\P=A/\Q \/ A/\P .=A/\(Q\/P) by XBOOLE_1:23
      .=A by A5,XBOOLE_1:21;
A29: now
      assume B/\P={};
      then B/\Q=B/\P \/ B/\Q .=B/\(P\/Q) by XBOOLE_1:23
        .=B by A5,XBOOLE_1:21;
      hence contradiction by A22,A28,XBOOLE_1:18;
    end;
    set P3=B/\Q,Q3=B/\P;
A30: Q3\/P3=B/\(P\/Q) by XBOOLE_1:23
      .=B by A5,XBOOLE_1:21;
A31: P3 misses Q3 by A8,XBOOLE_1:76;
    P3^b c= Q^b & Q3 c= P by FIN_TOPO:14,XBOOLE_1:17;
    then
A32: P3^b misses Q3 by A11,XBOOLE_1:64;
    B/\Q=A/\Q \/ B/\Q by A27
      .=(A\/B)/\Q by XBOOLE_1:23
      .=Q by A5,XBOOLE_1:21;
    hence contradiction by A3,A7,A29,A30,A31,A32;
  end;
  P2^b c= P^b & Q2 c= Q by FIN_TOPO:14,XBOOLE_1:17;
  then
A33: P2^b misses Q2 by A9,XBOOLE_1:64;
  P2\/Q2=A/\(P\/Q) by XBOOLE_1:23
    .=A by A5,XBOOLE_1:21;
  hence contradiction by A2,A15,A26,A10,A33;
end;
