reserve i,j,k,i1,j1 for Nat,
  p for Point of TOP-REAL 2,
  x for set;
reserve f for non constant standard special_circular_sequence;
reserve P for Subset of TOP-REAL 2;

theorem
  for j st 1 <= j & j+2 <= width GoB f holds LSeg(1/2*((GoB f)*(len GoB
  f,j)+(GoB f)*(len GoB f,j+1))+|[1,0]|, 1/2*((GoB f)*(len GoB f,j+1)+(GoB f)*(
  len GoB f,j+2))+|[1,0]|) misses L~f
proof
  let j such that
A1: 1 <= j and
A2: j+2 <= width GoB f;
A3: 1 <= len GoB f by GOBOARD7:32;
  now
A4: j <= j+2 by NAT_1:11;
    then j <= width GoB f by A2,XXREAL_0:2;
    then
A5: (GoB f)*(len GoB f,j)`1 = (GoB f)*(len GoB f,1)`1 by A1,A3,GOBOARD5:2;
    j+1 <= j+2 by XREAL_1:6;
    then 1 <= j+1 & j+1 <= width GoB f by A2,NAT_1:11,XXREAL_0:2;
    then
A6: (GoB f)*(len GoB f,j+1)`1 = (GoB f)*(len GoB f,1)`1 by A3,GOBOARD5:2;
    1 <= j+2 by A1,A4,XXREAL_0:2;
    then
A7: (GoB f)*(len GoB f,j+2)`1 = (GoB f)*(len GoB f,1)`1 by A2,A3,GOBOARD5:2;
    (1/2*((GoB f)*(len GoB f,j+1)+(GoB f)*(len GoB f,j+2))+|[1,0]|)`1 = (
1/2*((GoB f)*(len GoB f,j+1)+(GoB f)*(len GoB f,j+2)))`1+|[1,0]|`1 by
TOPREAL3:2
      .= 1/2*((GoB f)*(len GoB f,j+1)+(GoB f)*(len GoB f,j+2))`1+|[1,0]|`1
    by TOPREAL3:4
      .= 1/2*((GoB f)*(len GoB f,1)`1+(GoB f)*(len GoB f,1)`1)+|[1,0]|`1 by A6
,A7,TOPREAL3:2
      .= 1*((GoB f)*(len GoB f,1))`1+1 by EUCLID:52;
    then
A8: 1/2*((GoB f)*(len GoB f,j+1)+(GoB f)*(len GoB f,j+2))+|[1,0]| = |[(
GoB f)*(len GoB f,1)`1+1,(1/2*((GoB f)*(len GoB f,j+1) +(GoB f)*(len GoB f,j+2)
    )+|[1,0]|)`2]| by EUCLID:53;
    (1/2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1))+|[1,0]|)`1 = (1/
2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1)))`1+|[1,0]|`1 by TOPREAL3:2
      .= 1/2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1))`1+|[1,0]|`1 by
TOPREAL3:4
      .= 1/2*((GoB f)*(len GoB f,1)`1+(GoB f)*(len GoB f,1)`1)+|[1,0]|`1 by A5
,A6,TOPREAL3:2
      .= 1*((GoB f)*(len GoB f,1))`1+1 by EUCLID:52;
    then
A9: 1/2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1))+|[1,0]| = |[(GoB
f)*(len GoB f,1)`1+1,(1/2*((GoB f)*(len GoB f,j) +(GoB f)*(len GoB f,j+1))+|[1,
    0]|)`2]| by EUCLID:53;
    let p;
    assume p in LSeg(1/2*((GoB f)*(len GoB f,j)+(GoB f)*(len GoB f,j+1))+|[1,
    0]|, 1/2*((GoB f)*(len GoB f,j+1)+(GoB f)*(len GoB f,j+2))+|[1,0]|);
    then p`1 = (GoB f)*(len GoB f,1)`1 + 1 by A9,A8,TOPREAL3:11;
    hence p`1 > (GoB f)*(len GoB f,1)`1 by XREAL_1:29;
  end;
  hence thesis by Th22;
end;
