reserve S for non empty satisfying_Tarski-model
              TarskiGeometryStruct,
        a,b,c,d,c9,x,y,z,p,q,q9 for POINT of S;
reserve              S for satisfying_Tarski-model TarskiGeometryStruct,
        a,a9,b,b9,c,c9 for POINT of S;
reserve S                 for non empty satisfying_Tarski-model
                                    TarskiGeometryStruct,
        A,A9              for Subset of S,
        x,y,z,a,b,c,c9,d,u,p,q,q9 for POINT of S;
reserve S                 for non empty
                            satisfying_Lower_Dimension_Axiom
                            satisfying_Tarski-model
                            TarskiGeometryStruct,
        a,b,c,p,q,x,y,z,t for POINT of S;

theorem Lemma8p20:
  right_angle a,b,c & Middle reflection(a,c),p,reflection(b,c) implies
  right_angle b,a,p & (b <> c implies a <> p)
  proof
    assume that
A1: right_angle a,b,c and
A2: Middle reflection(a,c),p,reflection(b,c);
    set d  = reflection(b,c),
        b9 = reflection(a,b),
        c9 = reflection(a,c),
        d9 = reflection(a,d),
        p9 = reflection(a,p);
A3: right_angle b9,b,c
    proof
      per cases;
      suppose a = b;
        then reflection(a,b) = b by GTARSKI3:104;
        hence thesis by Satz8p2,Satz8p5;
      end;
      suppose
A4:     a <> b;
        Middle b,a,b9 by GTARSKI3:def 13;
        then between b,a,b9 by GTARSKI3:def 12;
        then Collinear b,a,b9 by GTARSKI1:def 17;
        hence thesis by A1,A4,Satz8p3;
      end;
    end;
A5: b9,b equiv b,b9
    proof
      b9,b equiv reflection(a,reflection(a,b)),reflection(a,b)
        by GTARSKI3:105;
      hence thesis by GTARSKI3:101;
    end;
A6: b9,c equiv b,c9
    proof
      b9,c equiv reflection(a,b9),reflection(a,c) by GTARSKI3:105;
      hence thesis by GTARSKI3:101;
    end;
    b9,b,c cong b,b9,c9
    proof
      b,c equiv b9,c9 by GTARSKI3:105;
      hence thesis by A5,A6,GTARSKI1:def 3;
    end; then
A7: right_angle b,b9,c9 by A3,Satz8p10;
A8: reflection(b9,c9) = d9 by Prelim12,GTARSKI3:100;
    c9,p,d,b IFS d9,p9,c,b
    proof
      now
        thus between c9,p,d by A2,GTARSKI3:def 12;
        between d,p,c9 by A2,GTARSKI3:14,def 12;
        then between reflection(a,d),reflection(a,p),reflection(a,c9)
          by GTARSKI3:106;
        hence between d9,p9,c by GTARSKI3:101;
        reflection(a,c),reflection(b,c) equiv
          reflection(a,(reflection(a,c))),reflection(a,reflection(b,c))
          by GTARSKI3:105;
        then reflection(a,c),reflection(b,c) equiv
          c,reflection(a,reflection(b,c)) by GTARSKI3:101;
        hence c9,d equiv d9,c by GTARSKI3:7;
        now
          thus p,d equiv p9,d9 by GTARSKI3:105;
A9:       p,c9 equiv p,d by A2,GTARSKI3:def 12;
          p,c9 equiv reflection(a,p),reflection(a,c9) by GTARSKI3:105;
          then
A10:      p,c9 equiv p9,c by GTARSKI3:101;
          p,d equiv reflection(a,p),reflection(a,d) by GTARSKI3:105;
          then p,c9 equiv reflection(a,p),reflection(a,d) by A9,GTARSKI3:5;
          then reflection(a,p),reflection(a,d) equiv p,c9 by GTARSKI3:4;
          hence p9,d9 equiv p9,c by A10,GTARSKI3:5;
        end;
        hence p,d equiv p9,c by GTARSKI3:5;
        c9,b equiv b,d9 by A8,A7,GTARSKI3:6;
        hence c9,b equiv d9,b by GTARSKI3:7;
        Middle c,b,d by GTARSKI3:def 13;
        then b,d equiv b,c by GTARSKI3:4,def 12;
        then d,b equiv b,c by GTARSKI3:6;
        hence d,b equiv c,b by GTARSKI3:7;
      end;
      hence thesis by GTARSKI3:def 5;
    end;
    then b,p equiv p9,b by GTARSKI3:6,41;
    hence right_angle b,a,p by GTARSKI3:7;
    thus b <> c implies a <> p
    proof
      assume
A11:  b <> c;
      assume
A12:  a = p;
      c = reflection(a,c9) by GTARSKI3:101
       .= d by A12,A2,GTARSKI3:def 13;
      then Middle c,b,c by GTARSKI3:def 13;
      hence thesis by GTARSKI3:97,A11;
    end;
  end;
