reserve T,T1,T2,S for non empty TopSpace;
reserve p,q for Point of TOP-REAL 2;

theorem Th34:
  for K1 being non empty Subset of TOP-REAL 2, f being Function of
  (TOP-REAL 2)|K1,R^1 st (for p being Point of (TOP-REAL 2) st p in the carrier
of (TOP-REAL 2)|K1 holds f.p=p`1/p`2/p`2) & (for q being Point of TOP-REAL 2 st
  q in the carrier of (TOP-REAL 2)|K1 holds q`2<>0 ) holds f is continuous
proof
  let K1 be non empty Subset of TOP-REAL 2, f be Function of (TOP-REAL 2)|K1,
  R^1;
  assume that
A1: for p being Point of (TOP-REAL 2) st p in the carrier of (TOP-REAL 2
  )| K1 holds f.p=p`1/p`2/p`2 and
A2: for q being Point of TOP-REAL 2 st q in the carrier of (TOP-REAL 2)
  |K1 holds q`2<>0;
  reconsider g2=proj1|K1 as Function of (TOP-REAL 2)|K1,R^1 by TOPMETR:17;
  reconsider g1=proj2|K1 as Function of (TOP-REAL 2)|K1,R^1 by TOPMETR:17;
A3: the carrier of (TOP-REAL 2)|K1=[#]((TOP-REAL 2)|K1)
    .=K1 by PRE_TOPC:def 5;
A4: for q being Point of (TOP-REAL 2)|K1 holds g1.q=proj2.q
  proof
    let q be Point of (TOP-REAL 2)|K1;
    q in the carrier of (TOP-REAL 2)|K1 & dom proj2=the carrier of
    TOP-REAL 2 by FUNCT_2:def 1;
    then q in dom proj2 /\ K1 by A3,XBOOLE_0:def 4;
    hence thesis by FUNCT_1:48;
  end;
  then
A5: g1 is continuous by Th30;
A6: for q being Point of (TOP-REAL 2)|K1 holds g1.q<>0
  proof
    let q be Point of (TOP-REAL 2)|K1;
    q in the carrier of (TOP-REAL 2)|K1;
    then reconsider q2=q as Point of TOP-REAL 2 by A3;
    g1.q=proj2.q by A4
      .=q2`2 by PSCOMP_1:def 6;
    hence thesis by A2;
  end;
A7: for q being Point of (TOP-REAL 2)|K1 holds g2.q=proj1.q
  proof
    let q be Point of (TOP-REAL 2)|K1;
    q in the carrier of (TOP-REAL 2)|K1 & dom proj1=the carrier of
    TOP-REAL 2 by FUNCT_2:def 1;
    then q in dom proj1 /\ K1 by A3,XBOOLE_0:def 4;
    hence thesis by FUNCT_1:48;
  end;
  then g2 is continuous by Th29;
  then consider g3 being Function of (TOP-REAL 2)|K1,R^1 such that
A8: for q being Point of (TOP-REAL 2)|K1,r1,r2 being Real st g2.
  q= r1 & g1.q=r2 holds g3.q=r1/r2/r2 and
A9: g3 is continuous by A5,A6,Th28;
A10: for x being object st x in dom f holds f.x=g3.x
  proof
    let x be object;
    assume
A11: x in dom f;
    then reconsider s=x as Point of (TOP-REAL 2)|K1;
    x in [#]((TOP-REAL 2)|K1) by A11;
    then x in K1 by PRE_TOPC:def 5;
    then reconsider r=x as Point of (TOP-REAL 2);
A12: proj1.r=r`1 & proj2.r=r`2 by PSCOMP_1:def 5,def 6;
A13: g2.s=proj1.s & g1.s=proj2.s by A7,A4;
    f.r=r`1/r`2/r`2 by A1,A11;
    hence thesis by A8,A13,A12;
  end;
  dom g3=the carrier of (TOP-REAL 2)|K1 by FUNCT_2:def 1;
  then dom f=dom g3 by FUNCT_2:def 1;
  hence thesis by A9,A10,FUNCT_1:2;
end;
