reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th34:
  for sn being Real,x,K0 being set st -1<sn & sn<1 & x in K0 & K0=
  {p: p`1<=0 & p<>0.TOP-REAL 2} holds (sn-FanMorphW).x in K0
proof
  let sn be Real,x,K0 be set;
  assume
A1: -1<sn & sn<1 & x in K0 & K0={p: p`1<=0 & p<>0.TOP-REAL 2};
  then consider p such that
A2: p=x and
A3: p`1<=0 and
A4: p<>0.TOP-REAL 2;
A5: now
    assume |.p.|<=0;
    then |.p.|=0;
    hence contradiction by A4,TOPRNS_1:24;
  end;
  then
A6: (|.p.|)^2>0 by SQUARE_1:12;
  per cases;
  suppose
A7: p`2/|.p.|<=sn;
    reconsider p9= (sn-FanMorphW).p as Point of TOP-REAL 2;
    (sn-FanMorphW).p= |[ |.p.|*(-sqrt(1-((p`2/|.p.|-sn)/(1+sn))^2)), |.p
    .|*((p`2/|.p.|-sn)/(1+sn))]| by A1,A3,A4,A7,Th18;
    then
A8: p9`1=|.p.|*(-sqrt(1-((p`2/|.p.|-sn)/(1+sn))^2)) by EUCLID:52;
A9: (|.p.|)^2 =(p`1)^2+(p`2)^2 by JGRAPH_3:1;
A10: 1+sn>0 by A1,XREAL_1:148;
    per cases;
    suppose
      p`1=0;
      hence thesis by A1,A2,Th16;
    end;
    suppose
      p`1<>0;
      then 0+(p`2)^2<(p`1)^2+(p`2)^2 by SQUARE_1:12,XREAL_1:8;
      then (p`2)^2/(|.p.|)^2 < (|.p.|)^2/(|.p.|)^2 by A6,A9,XREAL_1:74;
      then (p`2)^2/(|.p.|)^2 < 1 by A6,XCMPLX_1:60;
      then ((p`2)/|.p.|)^2 < 1 by XCMPLX_1:76;
      then -1 < p`2/|.p.| by SQUARE_1:52;
      then -1-sn< p`2/|.p.|-sn by XREAL_1:9;
      then (-1)*(1+sn)/(1+sn)< (p`2/|.p.|-sn)/(1+sn) by A10,XREAL_1:74;
      then
A11:  -1< (p`2/|.p.|-sn)/(1+sn) by A10,XCMPLX_1:89;
      p`2/|.p.|-sn<=0 by A7,XREAL_1:47;
      then 1^2> ((p`2/|.p.|-sn)/(1+sn))^2 by A10,A11,SQUARE_1:50;
      then 1-((p`2/|.p.|-sn)/(1+sn))^2>0 by XREAL_1:50;
      then --sqrt(1-((p`2/|.p.|-sn)/(1+sn))^2)>0 by SQUARE_1:25;
      then -sqrt(1-((p`2/|.p.|-sn)/(1+sn))^2)<0;
      then |.p.|*(-sqrt(1-((p`2/|.p.|-sn)/(1+sn))^2))<0 by A5,XREAL_1:132;
      hence thesis by A1,A2,A8,JGRAPH_2:3;
    end;
  end;
  suppose
A12: p`2/|.p.|>sn;
    reconsider p9= (sn-FanMorphW).p as Point of TOP-REAL 2;
    (sn-FanMorphW).p= |[ |.p.|*(-sqrt(1-((p`2/|.p.|-sn)/(1-sn))^2)), |.p
    .|*((p`2/|.p.|-sn)/(1-sn))]| by A1,A3,A4,A12,Th18;
    then
A13: p9`1=|.p.|*(-sqrt(1-((p`2/|.p.|-sn)/(1-sn))^2)) by EUCLID:52;
A14: (|.p.|)^2 =(p`1)^2+(p`2)^2 by JGRAPH_3:1;
A15: 1-sn>0 by A1,XREAL_1:149;
    per cases;
    suppose
      p`1=0;
      hence thesis by A1,A2,Th16;
    end;
    suppose
      p`1<>0;
      then 0+(p`2)^2<(p`1)^2+(p`2)^2 by SQUARE_1:12,XREAL_1:8;
      then (p`2)^2/(|.p.|)^2 < (|.p.|)^2/(|.p.|)^2 by A6,A14,XREAL_1:74;
      then (p`2)^2/(|.p.|)^2 < 1 by A6,XCMPLX_1:60;
      then ((p`2)/|.p.|)^2 < 1 by XCMPLX_1:76;
      then p`2/|.p.|<1 by SQUARE_1:52;
      then (p`2/|.p.|-sn)<1-sn by XREAL_1:9;
      then (p`2/|.p.|-sn)/(1-sn)<(1-sn)/(1-sn) by A15,XREAL_1:74;
      then
A16:  (p`2/|.p.|-sn)/(1-sn)<1 by A15,XCMPLX_1:60;
      -(1-sn)< -0 & p`2/|.p.|-sn>=sn-sn by A12,A15,XREAL_1:9,24;
      then (-1)*(1-sn)/(1-sn)< (p`2/|.p.|-sn)/(1-sn) by A15,XREAL_1:74;
      then -1< (p`2/|.p.|-sn)/(1-sn) by A15,XCMPLX_1:89;
      then 1^2> ((p`2/|.p.|-sn)/(1-sn))^2 by A16,SQUARE_1:50;
      then 1-((p`2/|.p.|-sn)/(1-sn))^2>0 by XREAL_1:50;
      then --sqrt(1-((p`2/|.p.|-sn)/(1-sn))^2)>0 by SQUARE_1:25;
      then -sqrt(1-((p`2/|.p.|-sn)/(1-sn))^2)<0;
      then p9`1<0 by A5,A13,XREAL_1:132;
      hence thesis by A1,A2,JGRAPH_2:3;
    end;
  end;
end;
