reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th34:
  LMP C in South_Arc C
proof
  set w = (W-bound C + E-bound C) / 2;
  set p = LMP C;
  set U = {LMP Lower_Arc L~Cage(C,n) where n is Nat: 0 < n};
  set n0 = S-bound L~Cage(C,1);
  set H = LSeg(p,|[w,n0]|);
A1: |[w,S-bound C]|`1 = w by EUCLID:52;
A2: |[w,n0]|`1 = w by EUCLID:52;
  {LMP Lower_Arc L~Cage(C,n) where n is Nat: 0 < n} c= the
  carrier of TOP-REAL 2
  proof
    let x be object;
    assume x in {LMP Lower_Arc L~Cage(C,n) where n is Nat: 0 < n};
    then ex n being Nat st x = LMP Lower_Arc L~Cage(C,n) & 0 < n;
    hence thesis;
  end;
  then reconsider U as Subset of TOP-REAL 2;
  set q = upper_bound(proj2.:(H /\ U));
  set S = LSeg(|[w,q]|, |[w,n0]|);
A3: |[w,S-bound C]|`2 = S-bound C by EUCLID:52;
A4: |[w,n0]|`2 = n0 by EUCLID:52;
A5: for n being Nat holds (LMP Lower_Arc L~Cage(C,n))`1 = w
  proof
    let n be Nat;
A6: W-bound L~Cage(C,n) + E-bound L~Cage(C,n) = W-bound C + E-bound C by
JORDAN1G:33;
    thus (LMP Lower_Arc L~Cage(C,n))`1 = (W-bound Lower_Arc L~Cage(C,n) +
    E-bound Lower_Arc L~Cage(C,n))/2 by EUCLID:52
      .= (W-bound L~Cage(C,n) + E-bound Lower_Arc L~Cage(C,n))/2 by JORDAN21:19
      .= w by A6,JORDAN21:20;
  end;
A7: p`2 >= (LMP Lower_Arc L~Cage(C,1))`2 by Th24;
A8: LSeg(p, |[w, S-bound C]|) /\ C = {p} by JORDAN21:35;
A9: (LMP Lower_Arc L~Cage(C,1))`2 >= n0 by JORDAN21:48;
  H /\ U is bounded by TOPREAL6:89;
  then proj2.:(H /\ U) is real-bounded by JCT_MISC:14;
  then
A10: proj2.:(H /\ U) is bounded_above;
A11: p`1 = w by EUCLID:52;
A12: for n being Nat st 0 < n holds (LMP Lower_Arc L~Cage(C,n))`2
  in proj2.:(H /\ U)
  proof
    let n be Nat;
    set f = Cage(C,n);
    set s = LMP Lower_Arc L~f;
    assume
A13: 0 < n;
    then
A14: s in U;
    0+1 <= n by A13,NAT_1:13;
    then n = 1 or n > 1 by XXREAL_0:1;
    then
A15: S-bound L~Cage(C,n) >= S-bound L~Cage(C,1) by JORDAN1A:69;
    S-bound L~f <= s`2 by JORDAN21:48;
    then
A16: s`2 >= n0 by A15,XXREAL_0:2;
A17: s`1 = w by A5;
    p`2 >= s`2 by A13,Th24;
    then s in H by A2,A4,A11,A16,A17,GOBOARD7:7;
    then
A18: s in H /\ U by A14,XBOOLE_0:def 4;
    s`2 = proj2.s by PSCOMP_1:def 6;
    hence thesis by A18,FUNCT_2:35;
  end;
  then
A19: (LMP Lower_Arc L~Cage(C,1))`2 in proj2.:(H /\ U);
  then q >= (LMP Lower_Arc L~Cage(C,1))`2 by A10,SEQ_4:def 1;
  then
A20: q >= n0 by A9,XXREAL_0:2;
A21: |[w,q]|`1 = w by EUCLID:52;
  then
A22: S is vertical by A2,SPPOL_1:16;
A23: |[w,q]| in S by RLTOPSP1:68;
A24: |[w,q]|`2 = q by EUCLID:52;
  per cases;
  suppose
A25: p <> |[w,q]|;
    consider S9,C9 being Subset of TopSpaceMetr Euclid 2 such that
A26: S = S9 and
A27: C = C9 and
A28: dist_min(S,C) = min_dist_min(S9,C9) by JORDAN1K:def 1;
A29: S9 is compact by A26,Lm4,COMPTS_1:23;
A30: C9 is compact by A27,Lm4,COMPTS_1:23;
A31: now
      assume
A32:  p`2 <= q;
      per cases by A32,XXREAL_0:1;
      suppose
        p`2 = q;
        hence contradiction by A25,EUCLID:52;
      end;
      suppose
        p`2 < q;
        then 0 < q - p`2 by XREAL_1:50;
        then consider r being Real such that
A33:    r in proj2.:(H /\ U) and
A34:    q-(q-p`2) < r by A10,A19,SEQ_4:def 1;
        consider t being Point of TOP-REAL 2 such that
A35:    t in H /\ U and
A36:    proj2.t = r by A33,Lm1;
A37:    t in H by A35,XBOOLE_0:def 4;
A38:    p`2 >= n0 by A9,A7,XXREAL_0:2;
        t`2 = r by A36,PSCOMP_1:def 6;
        hence contradiction by A4,A34,A38,A37,TOPREAL1:4;
      end;
    end;
    S misses C
    proof
      assume S meets C;
      then consider x being object such that
A39:  x in S and
A40:  x in C by XBOOLE_0:3;
      reconsider x as Point of TOP-REAL 2 by A39;
A41:  x`2 >= S-bound C by A40,PSCOMP_1:24;
A42:  x`1 = w by A21,A23,A22,A39,SPPOL_1:def 3;
A43:  q >= x`2 by A4,A24,A20,A39,TOPREAL1:4;
      then p`2 > x`2 by A31,XXREAL_0:2;
      then x in LSeg(p, |[w, S-bound C]|) by A1,A3,A11,A41,A42,GOBOARD7:7;
      then x in {p} by A8,A40,XBOOLE_0:def 4;
      hence contradiction by A31,A43,TARSKI:def 1;
    end;
    then dist_min(S,C) > 0 by A26,A27,A28,A29,A30,JGRAPH_1:38;
    then dist_min(S,C)/2 > 0;
    then consider k being Nat such that
A44: 1 < k and
A45: dist(Gauge(C,k)*(1,1),Gauge(C,k)*(1,2)) < dist_min(S,C)/2 and
A46: dist(Gauge(C,k)*(1,1),Gauge(C,k)*(2,1)) < dist_min(S,C)/2 by GOBRD14:11;
    set f = Cage(C,k), G = Gauge(C,k);
    set s = LMP Lower_Arc L~f;
A47: s`2 >= S-bound L~f by JORDAN21:48;
A48: dist(G*(1,1),G*(1+1,1)) + dist(G*(1,1),G*(1,1+1)) < dist_min(S,C)/2 +
    dist_min(S,C)/2 by A45,A46,XREAL_1:8;
    S-bound L~Cage(C,k) >= S-bound L~Cage(C,1) by A44,JORDAN1A:69;
    then
A49: s`2 >= n0 by A47,XXREAL_0:2;
    s`2 in proj2.:(H /\ U) by A12,A44;
    then
A50: q >= s`2 by A10,SEQ_4:def 1;
    [1,1+1] in Indices G by Th6;
    then
A51: dist(G*(1,1),G*(1,1+1)) = (N-bound C - S-bound C)/2|^k by Th5,GOBRD14:9;
    [1+1,1] in Indices G by Th7;
    then
A52: dist(G*(1,1),G*(1+1,1)) = (E-bound C - W-bound C)/2|^k by Th5,GOBRD14:10;
A53: s in Lower_Arc L~f by JORDAN21:31;
    Lower_Arc L~f c= L~f by JORDAN6:61;
    then consider i being Nat such that
A54: 1 <= i and
A55: i+1 <= len f and
A56: s in LSeg(f,i) by A53,SPPOL_2:13;
A57: f is_sequence_on G by JORDAN9:def 1;
    then consider i1,j1,i2,j2 being Nat such that
A58: [i1,j1] in Indices G and
A59: f/.i = G*(i1,j1) and
A60: [i2,j2] in Indices G and
A61: f/.(i+1) = G*(i2,j2) and
A62: i1 = i2 & j1+1 = j2 or i1+1 = i2 & j1 = j2 or i1 = i2+1 & j1 = j2
    or i1 = i2 & j1 = j2+1 by A54,A55,JORDAN8:3;
A63: 1 <= i1 by A58,MATRIX_0:32;
    right_cell(f,i,G) meets C by A54,A55,JORDAN9:31;
    then consider c being object such that
A64: c in right_cell(f,i,G) and
A65: c in C by XBOOLE_0:3;
    reconsider c as Point of TOP-REAL 2 by A65;
    reconsider s9 = s, c9 = c as Point of Euclid 2 by EUCLID:67;
    s`1 = w by A5;
    then s in S by A2,A4,A21,A24,A49,A50,GOBOARD7:7;
    then
A66: min_dist_min(S9,C9) <= dist(s9,c9) by A26,A27,A29,A30,A65,WEIERSTR:34;
A67: dist(s9,c9) = dist(s,c) by TOPREAL6:def 1;
A68: 1 <= j2 by A60,MATRIX_0:32;
    left_cell(f,i,G) /\ right_cell(f,i,G) = LSeg(f,i) by A54,A55,A57,GOBRD13:29
;
    then
A69: s in right_cell(f,i,G) by A56,XBOOLE_0:def 4;
A70: j2 <= width G by A60,MATRIX_0:32;
A71: j2+1+1<>j2;
A72: 1 <= i2 by A60,MATRIX_0:32;
A73: j1 <= width G by A58,MATRIX_0:32;
A74: 1 <= j1+1 by NAT_1:11;
A75: i1+1<>i1+0;
A76: i1 <= len G by A58,MATRIX_0:32;
A77: i2 <= len G by A60,MATRIX_0:32;
A78: i2+1+1<>i2;
A79: 1 <= j1 by A58,MATRIX_0:32;
A80: 1 <= i1+1 by NAT_1:11;
    now
      per cases by A62;
      suppose
A81:    i1 = i2 & j1+1 = j2;
        then
A82:    dist(G*(i1,j1),G*(i1,j1+1)) = (N-bound C - S-bound C)/2|^k by A58,A60,
GOBRD14:9;
A83:    dist(G*(i1,j1),G*(i1,j1+1)) = G*(i1,j1+1)`2 - G*(i1,j1)`2 by A58,A60
,A81,GOBRD14:6;
        i1 < len G by A54,A55,A58,A59,A60,A61,A81,JORDAN10:1;
        then
A84:    i1+1 <= len G by NAT_1:13;
        then
A85:    [i1+1,j1] in Indices G by A79,A80,A73,MATRIX_0:30;
        then
A86:    dist(G*(i1,j1),G*(i1+1,j1)) = G*(i1+1,j1)`1 - G*(i1,j1)`1 by A58,
GOBRD14:5;
A87:    dist(G*(i1,j1),G*(i1+1,j1)) = (E-bound C - W-bound C)/2|^k by A58,A85,
GOBRD14:10;
A88:    j1+1 <= width G by A60,A81,MATRIX_0:32;
A89:    right_cell(f,i,G) = cell(G,i1,j1) by A54,A55,A57,A58,A59,A60,A61,A75
,A71,A81,GOBRD13:def 2;
        then
A90:    c`1 <= G*(i1+1,j1)`1 by A64,A63,A79,A88,A84,JORDAN9:17;
A91:    s`2 <= G*(i1,j1+1)`2 by A69,A63,A79,A88,A84,A89,JORDAN9:17;
A92:    G*(i1,j1)`2 <= s`2 by A69,A63,A79,A88,A84,A89,JORDAN9:17;
A93:    s`1 <= G*(i1+1,j1)`1 by A69,A63,A79,A88,A84,A89,JORDAN9:17;
A94:    G*(i1,j1)`1 <= s`1 by A69,A63,A79,A88,A84,A89,JORDAN9:17;
A95:    c`2 <= G*(i1,j1+1)`2 by A64,A63,A79,A88,A84,A89,JORDAN9:17;
A96:    G*(i1,j1)`2 <= c`2 by A64,A63,A79,A88,A84,A89,JORDAN9:17;
        G*(i1,j1)`1 <= c`1 by A64,A63,A79,A88,A84,A89,JORDAN9:17;
        then dist(s,c) <= (G*(i1+1,j1)`1-G*(i1,j1)`1) + (G*(i1,j1+1)`2- G*(i1
        ,j1)`2) by A90,A96,A95,A94,A93,A92,A91,TOPREAL6:95;
        hence contradiction by A28,A48,A66,A67,A51,A52,A86,A83,A82,A87,
XXREAL_0:2;
      end;
      suppose
A97:    i1+1 = i2 & j1 = j2;
        then 1 < j1 by A54,A55,A58,A59,A60,A61,JORDAN10:3;
        then
A98:    1 <= j1-'1 by NAT_D:49;
        then
A99:    j1-'1+1 = j1 by NAT_D:43;
A100:   j1-'1 <= width G by A73,NAT_D:44;
        then
A101:   [i1,j1-'1] in Indices G by A63,A76,A98,MATRIX_0:30;
        then
A102:   dist(G*(i1,j1-'1),G*(i1,j1-'1+1)) = G*(i1,j1-'1+1)`2 - G*(i1,j1
        -'1)`2 by A58,A99,GOBRD14:6;
A103:   [i1+1,j1-'1] in Indices G by A72,A77,A97,A98,A100,MATRIX_0:30;
        then
A104:   dist(G*(i1,j1-'1),G*(i1+1,j1-'1)) = G*(i1+1,j1-'1)`1 - G*( i1,
        j1-'1)`1 by A101,GOBRD14:5;
A105:   dist(G*(i1,j1-'1),G*(i1,j1-'1+1)) = (N-bound C - S-bound C)/2|^k
        by A58,A99,A101,GOBRD14:9;
A106:   dist(G*(i1,j1-'1),G*(i1+1,j1-'1)) = (E-bound C - W-bound C)/2|^k
        by A101,A103,GOBRD14:10;
A107:   i1+1 <= len G by A60,A97,MATRIX_0:32;
A108:   right_cell(f,i,G) = cell(G,i1,j1-'1) by A54,A55,A57,A58,A59,A60,A61,A75
,A78,A97,GOBRD13:def 2;
        then
A109:   c`1 <= G*(i1+1,j1-'1)`1 by A64,A63,A73,A107,A98,A99,JORDAN9:17;
A110:   s`2 <= G*(i1,j1-'1+1)`2 by A69,A63,A73,A107,A98,A99,A108,JORDAN9:17;
A111:   G*(i1,j1-'1)`2 <= s`2 by A69,A63,A73,A107,A98,A99,A108,JORDAN9:17;
A112:   s`1 <= G*(i1+1,j1-'1)`1 by A69,A63,A73,A107,A98,A99,A108,JORDAN9:17;
A113:   G*(i1,j1-'1)`1 <= s`1 by A69,A63,A73,A107,A98,A99,A108,JORDAN9:17;
A114:   c`2 <= G*(i1,j1-'1+1)`2 by A64,A63,A73,A107,A98,A99,A108,JORDAN9:17;
A115:   G*(i1,j1-'1)`2 <= c`2 by A64,A63,A73,A107,A98,A99,A108,JORDAN9:17;
        G*(i1,j1-'1)`1 <= c`1 by A64,A63,A73,A107,A98,A99,A108,JORDAN9:17;
        then dist(s,c) <= (G*(i1+1,j1-'1)`1-G*(i1,j1-'1)`1) + (G*(i1,j1-'1+1)
        `2-G*(i1,j1-'1)`2) by A109,A115,A114,A113,A112,A111,A110,TOPREAL6:95;
        hence contradiction by A28,A48,A66,A67,A51,A52,A104,A102,A105,A106,
XXREAL_0:2;
      end;
      suppose
A116:   i1 = i2+1 & j1 = j2;
        then
A117:   dist(G*(i2,j2),G*(i2+1,j2)) = (E-bound C - W-bound C)/2|^k by A58,A60,
GOBRD14:10;
A118:   dist(G*(i2,j2),G*(i2+1,j2)) = G*(i2+1,j2)`1 - G*(i2,j2)`1 by A58,A60
,A116,GOBRD14:5;
A119:   i2+1 <= len G by A58,A116,MATRIX_0:32;
        j1 < width G by A54,A55,A58,A59,A60,A61,A116,JORDAN10:4;
        then
A120:   j1+1 <= width G by NAT_1:13;
        then
A121:   [i2,j2+1] in Indices G by A72,A74,A77,A116,MATRIX_0:30;
        then
A122:   dist(G*(i2,j2),G*(i2,j2+1)) = G*(i2,j2+1)`2 - G*(i2,j2)`2 by A60,
GOBRD14:6;
A123:   right_cell(f,i,G) = cell(G,i2,j2) by A54,A55,A57,A58,A59,A60,A61,A75
,A78,A116,GOBRD13:def 2;
        then
A124:   c`1 <= G*(i2+1,j2)`1 by A64,A79,A72,A116,A119,A120,JORDAN9:17;
A125:   s`2 <= G*(i2,j2+1)`2 by A69,A79,A72,A116,A119,A120,A123,JORDAN9:17;
A126:   G*(i2,j2)`2 <= c`2 by A64,A79,A72,A116,A119,A120,A123,JORDAN9:17;
A127:   dist(G*(i2,j2),G*(i2,j2+1)) = (N-bound C - S-bound C)/2|^k by A60,A121,
GOBRD14:9;
A128:   G*(i2,j2)`2 <= s`2 by A69,A79,A72,A116,A119,A120,A123,JORDAN9:17;
A129:   s`1 <= G*(i2+1,j2)`1 by A69,A79,A72,A116,A119,A120,A123,JORDAN9:17;
A130:   G*(i2,j2)`1 <= s`1 by A69,A79,A72,A116,A119,A120,A123,JORDAN9:17;
A131:   c`2 <= G*(i2,j2+1)`2 by A64,A79,A72,A116,A119,A120,A123,JORDAN9:17;
        G*(i2,j2)`1 <= c`1 by A64,A79,A72,A116,A119,A120,A123,JORDAN9:17;
        then dist(s,c) <= (G*(i2+1,j2)`1-G*(i2,j2)`1) + (G*(i2,j2+1)`2- G*(i2
        ,j2)`2) by A124,A126,A131,A130,A129,A128,A125,TOPREAL6:95;
        hence contradiction by A28,A48,A66,A67,A51,A52,A118,A122,A127,A117,
XXREAL_0:2;
      end;
      suppose
A132:   i1 = i2 & j1 = j2+1;
        then 1 < i1 by A54,A55,A58,A59,A60,A61,JORDAN10:2;
        then
A133:   1 <= i1-'1 by NAT_D:49;
A134:   i1-'1 <= len G by A76,NAT_D:44;
        then
A135:   [i1-'1,j2] in Indices G by A68,A70,A133,MATRIX_0:30;
A136:   [i1-'1,j2+1] in Indices G by A79,A73,A132,A133,A134,MATRIX_0:30;
        then
A137:   dist(G*(i1-'1,j2),G*(i1-'1,j2+1)) = G*(i1-'1,j2+1)`2 - G*( i1 -'
        1,j2)`2 by A135,GOBRD14:6;
A138:   dist(G*(i1-'1,j2),G*(i1-'1,j2+1)) = (N-bound C - S-bound C)/2|^k
        by A135,A136,GOBRD14:9;
A139:   j2+1 <= width G by A58,A132,MATRIX_0:32;
A140:   i1-'1+1 = i1 by A133,NAT_D:43;
        then
A141:   [i1-'1+1,j2] in Indices G by A63,A68,A76,A70,MATRIX_0:30;
        then
A142:   dist(G*(i1-'1,j2),G*(i1-'1+1,j2)) = G*(i1-'1+1,j2)`1 - G*( i1 -'
        1,j2)`1 by A135,GOBRD14:5;
A143:   right_cell(f,i,G) = cell(G,i1-'1,j2) by A54,A55,A57,A58,A59,A60,A61,A75
,A71,A132,GOBRD13:def 2;
        then
A144:   c`1 <= G*(i1-'1+1,j2)`1 by A64,A68,A76,A139,A133,A140,JORDAN9:17;
A145:   s`2 <= G*(i1-'1,j2+1)`2 by A69,A68,A76,A139,A133,A140,A143,JORDAN9:17;
A146:   G*(i1-'1,j2)`2 <= s`2 by A69,A68,A76,A139,A133,A140,A143,JORDAN9:17;
A147:   s`1 <= G*(i1-'1+1,j2)`1 by A69,A68,A76,A139,A133,A140,A143,JORDAN9:17;
A148:   G*(i1-'1,j2)`1 <= s`1 by A69,A68,A76,A139,A133,A140,A143,JORDAN9:17;
A149:   c`2 <= G*(i1-'1,j2+1)`2 by A64,A68,A76,A139,A133,A140,A143,JORDAN9:17;
A150:   G*(i1-'1,j2)`2 <= c`2 by A64,A68,A76,A139,A133,A140,A143,JORDAN9:17;
A151:   dist(G*(i1-'1,j2),G*(i1-'1+1,j2)) = (E-bound C - W-bound C)/2|^k
        by A135,A141,GOBRD14:10;
        G*(i1-'1,j2)`1 <= c`1 by A64,A68,A76,A139,A133,A140,A143,JORDAN9:17;
        then dist(s,c) <= (G*(i1-'1+1,j2)`1-G*(i1-'1,j2)`1) + (G*(i1-'1,j2+1)
        `2-G*(i1-'1,j2)`2) by A144,A150,A149,A148,A147,A146,A145,TOPREAL6:95;
        hence contradiction by A28,A48,A66,A67,A51,A52,A142,A137,A138,A151,
XXREAL_0:2;
      end;
    end;
    hence thesis;
  end;
  suppose
    p = |[w,q]|;
    then
A152: p`2 = q by EUCLID:52;
A153: ex S being Real_Sequence of 2 st S is convergent & (for x being
    Nat holds S.x in (Lower_Appr C).x) & p = lim S
    proof
      set R = {(LMP Lower_Arc L~Cage(C,n))`2 where n is Nat: 0 < n};
      R c= REAL
      proof
        let x be object;
        assume x in R;
        then ex n being Nat st x = (LMP Lower_Arc L~Cage(C,n))`2 &
        0 < n;
        hence thesis by XREAL_0:def 1;
      end;
      then reconsider R as Subset of REAL;
      deffunc g(Nat) = LMP Lower_Arc L~Cage(C,$1);
      reconsider pp = p as Element of REAL 2 by EUCLID:22;
A154: for x being Element of NAT holds g(x) is Element of REAL 2 by EUCLID:22;
      consider S being sequence of  REAL 2 such that
A155: for n being Element of NAT holds S.n = g(n) from FUNCT_2:sch 9
      (A154);
      the carrier of TOP-REAL 2 = REAL 2 by EUCLID:22;
      then reconsider SS=S as Real_Sequence of 2;
      take SS;
A156: R is bounded_above
      proof
        take q;
        let r be ExtReal;
        assume r in R;
        then ex n being Nat st r = (LMP Lower_Arc L~Cage(C,n))`2 &
        0 < n;
        then r in proj2.:(H /\ U) by A12;
        hence thesis by A10,SEQ_4:def 1;
      end;
A157: (LMP Lower_Arc L~Cage(C,1))`2 in R;
A158: for r being Real st 0<r ex n being Nat st for m being
      Nat st n<=m holds |. S.m-pp .| < r
      proof
A159:   for s being Real st 0<s ex r being Real st r in R & q-s<r
        proof
          let s be Real;
          assume 0<s;
          then consider r being Real such that
A160:     r in proj2.:(H /\ U) and
A161:     q-s<r by A10,A19,SEQ_4:def 1;
          take r;
          consider x being Point of TOP-REAL 2 such that
A162:     x in H /\ U and
A163:     proj2.x = r by A160,Lm1;
          x in U by A162,XBOOLE_0:def 4;
          then consider n being Nat such that
A164:     x = LMP Lower_Arc L~Cage(C,n) and
A165:     0 < n;
          r = (LMP Lower_Arc L~Cage(C,n))`2 by A163,A164,PSCOMP_1:def 6;
          hence thesis by A161,A165;
        end;
        reconsider p1=p as Element of TOP-REAL 2;
        let r be Real;
        assume 0 < r;
        then consider v being Real such that
A166:   v in R and
A167:   upper_bound R - r < v by A157,A156,SEQ_4:def 1;
        consider n being Nat such that
A168:   v = (LMP Lower_Arc L~Cage(C,n))`2 and
A169:   0 < n by A166;
        upper_bound R - r + r < v + r by A167,XREAL_1:6;
        then
A170:   upper_bound R - v < v + r - v by XREAL_1:14;
        take n;
        let m be Nat;
A171:     m in NAT by ORDINAL1:def 12;
        reconsider Sm = S.m as Point of TOP-REAL 2 by EUCLID:22;
        assume
A172:   n <= m;
        then (LMP Lower_Arc L~Cage(C,n))`2 <= (LMP Lower_Arc L~Cage(C,m))`2
        by A169,Th28;
        then (Sm)`2 >= v by A155,A168,A171;
        then
A173:   p`2 - (Sm)`2 <= p`2 - v by XREAL_1:13;
        reconsider SSm = Sm as Point of TOP-REAL 2;
A174:   SSm-p1 = S.m-pp;
A175:   S.m = LMP Lower_Arc L~Cage(C,m) by A155,A171;
        then (Sm)`1 = w by A5;
        then |.(Sm)`1-p`1.| = 0 by A11,ABSVALUE:def 1;
        then
A176:   |. S.m-pp .|<=0+|.(Sm)`2-p`2.| by A174,JGRAPH_1:32;
        0 > (Sm)`2-p`2 by A169,A175,A172,Th24,XREAL_1:49;
        then
A177:   |. S.m-pp .|<=-((Sm)`2-p`2) by A176,ABSVALUE:def 1;
        for r being Real st r in R holds q>=r
        proof
          let r be Real;
          assume r in R;
          then ex n being Nat st r = (LMP Lower_Arc L~Cage(C,n))`2
          & 0 < n;
          then r in proj2.:(H /\ U) by A12;
          hence thesis by A10,SEQ_4:def 1;
        end;
        then upper_bound R = q by A157,A156,A159,SEQ_4:def 1;
        then p`2-(Sm)`2 < r by A152,A170,A173,XXREAL_0:2;
        hence thesis by A177,XXREAL_0:2;
      end;
      thus
A178: SS is convergent
      proof
        take p;
        let r be Real;
        assume 0<r;
        then consider n being Nat such that
A179:   for m being Nat st n<=m holds |. S.m-pp .| < r by A158;
        take n;
        let m be Nat;
        assume n<=m;
        then |. S.m-pp .| < r by A179;
        hence |.SS.m-p.| < r;
      end;
      hereby
        let x be Nat;
A180:     x in NAT by ORDINAL1:def 12;
A181:   (Lower_Appr C).x = Lower_Arc L~Cage(C,x) by JORDAN19:def 2;
        S.x = LMP Lower_Arc L~Cage(C,x) by A155,A180;
        hence SS.x in (Lower_Appr C).x by A181,JORDAN21:31;
      end;
      for r being Real st 0<r
         ex n st for m st n<=m holds |.SS.m-p.| < r
      proof
        let r be Real;
        assume 0<r;
        then consider n being Nat such that
A182:   for m being Nat st n<=m holds |. S.m-pp .| < r by A158;
        take n;
        let m be Nat;
        assume n<=m;
        then |. S.m-pp .| < r by A182;
        hence |.SS.m-p.| < r;
      end;
      hence p = lim SS by A178,TOPRNS_1:def 9;
    end;
    South_Arc C = Lim_inf Lower_Appr C by JORDAN19:def 4;
    hence thesis by A153,KURATO_2:21;
  end;
end;
