reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th34:
  M is invertible iff Det M <> 0.K
proof
  thus M is invertible implies Det M <> 0.K
  proof
    reconsider N=n as Element of NAT by ORDINAL1:def 12;
    assume M is invertible;
    then consider M1 be Matrix of n,K such that
A1: M is_reverse_of M1 by MATRIX_6:def 3;
    per cases by NAT_1:14;
    suppose
      N=0;
      then Det M=1_K by MATRIXR2:41;
      hence thesis;
    end;
    suppose
A2:   N>=1;
A3:   M*M1=(1.(K,n)) by A1,MATRIX_6:def 2;
      Det (1.(K,n))=1_K by A2,MATRIX_7:16;
      then Det M*Det M1=1_K by A2,A3,MATRIX11:62;
      hence thesis;
    end;
  end;
  set C=(Det M)" * (Matrix_of_Cofactor M)@;
  assume
A4: Det M <> 0.K;
  then
A5: M*C=1.(K,n) by Th30;
  C*M=1.(K,n) by A4,Th33;
  then M is_reverse_of C by A5,MATRIX_6:def 2;
  hence thesis by MATRIX_6:def 3;
end;
