
theorem NachSpec:
  for L being distributive bounded Lattice holds
    L is Boolean iff Spectrum L is unordered
  proof
    let L be distributive bounded Lattice;
    thus L is Boolean implies Spectrum L is unordered
    proof
      assume L is Boolean; then
      reconsider LL = L as Boolean Lattice;
      assume not Spectrum L is unordered;
      then consider P, Q being set such that
F1:   P in Spectrum L & Q in Spectrum L & P <> Q &
        P, Q are_c=-comparable;
      consider P1 being Ideal of L such that
B1:   P1 = P & P1 is prime proper by F1;
      consider Q1 being Ideal of LL such that
b1:   Q1 = Q & Q1 is prime proper by F1;
A2:   now assume
f1:     P c= Q; then
        P c< Q by F1; then
        Q \ P <> {} by XBOOLE_1:105; then
        consider a being object such that
A4:     a in Q \ P by XBOOLE_0:def 1;
A5:     a in Q1 & not a in P1 by b1,B1,A4,XBOOLE_0:def 5; then
        reconsider a as Element of LL;
        Q1 <> (.LL.> by b1,SUBSET_1:def 6; then
        Q1 is max-ideal by FILTER_2:57,b1; then
B2:     not a` in P by f1,b1,A4,FILTER_2:58;
        a "/\" a` = Bottom LL by LATTICES:20; then
        a "/\" a` in P by FILTER_2:24,B1;
        hence contradiction by B1,A5,B2,FILTER_2:def 10;
      end;
      now assume
f1:     Q c= P; then
        Q c< P by F1; then
        P \ Q <> {} by XBOOLE_1:105; then
        consider a being object such that
A4:     a in P \ Q by XBOOLE_0:def 1;
A5:     a in P1 & not a in Q1 by B1,b1,A4,XBOOLE_0:def 5; then
        reconsider a as Element of LL;
        P1 <> (.LL.> by B1,SUBSET_1:def 6; then
        P1 is max-ideal by FILTER_2:57,B1; then
B2:     not a` in Q by f1,B1,A4,FILTER_2:58;
        a "/\" a` = Bottom LL by LATTICES:20; then
        a "/\" a` in Q1 by FILTER_2:24;
        hence contradiction by A5,B2,FILTER_2:def 10,b1;
      end;
      hence thesis by A2,F1;
    end;
    assume
d1: Spectrum L is unordered;
    assume not L is Boolean; then
    L is not complemented; then
    consider a being Element of L such that
C2: not ex b being Element of L st b is_a_complement_of a;
    set D = PseudoCocomplements a;
    reconsider D as Filter of L;
    set D1 = <.D \/ <.a.).);
II: D1 = { r where r is Element of L :
      ex d,q being Element of L st d "/\" q [= r & d in D & q in <.a.) }
        by FILTER_0:35;
AB: D1 c= { x where x is Element of L : ex d being Element of L st d in D &
       a "/\" d [= x }
    proof
      let t be object;
      assume t in D1; then
      consider r being Element of L such that
I1:   r = t &
      ex d,q being Element of L st d "/\" q [= r & d in D & q in <.a.) by II;
      consider d,q being Element of L such that
I2:   d "/\" q [= r & d in D & q in <.a.) by I1;
      a [= q by I2,FILTER_0:15; then
      d "/\" a [= d "/\" q by FILTER_0:5; then
      d "/\" a [= r by I2,LATTICES:7;
      hence thesis by I1,I2;
    end;
    { x where x is Element of L : ex d being Element of L st d in D &
       a "/\" d [= x } c= D1
    proof
      let t be object;
      assume t in { x where x is Element of L :
        ex d being Element of L st d in D & a "/\" d [= x }; then
      consider x1 being Element of L such that
a1:   x1 = t & ex d being Element of L st d in D & a "/\" d [= x1;
      consider d being Element of L such that
a2:   d in D & a "/\" d [= x1 by a1;
      set q = a;
      d "/\" q [= x1 & q in <.a.) by a2;
      hence thesis by a1,II;
    end; then
Z0: D1 = { x where x is Element of L : ex d being Element of L st d in D &
       a "/\" d [= x } by AB;
    a "/\" (the Element of D) [= a by LATTICES:6; then
HH: a in D1 by Z0;
    reconsider D1 as Filter of L;
HJ: not Bottom L in D1
    proof
      assume Bottom L in D1; then
      consider y being Element of L such that
Z1:   y = Bottom L &
      ex d being Element of L st d in D & a "/\" d [= y by Z0;
      consider d being Element of L such that
Z2:   d in D & d "/\" a [= y by Z1;
z4:   Bottom L [= d "/\" a;
      consider x being Element of L such that
Z3:   d = x & a "\/" x = Top L by Z2;
      d is_a_complement_of a by z4,Z3,Z1,Z2,LATTICES:8;
      hence thesis by C2;
    end;
    reconsider I0 = { Bottom L } as Ideal of L by FILTER_2:25;
    consider P being Ideal of L such that
W0: P is prime & I0 c= P & P misses D1 by Th15,ZFMISC_1:50,HJ;
    P <> the carrier of L by W0,XBOOLE_0:3,HH; then
w0: P is proper by SUBSET_1:def 6;
    set Pa = (.P \/ (.a.>.>;
    reconsider Pa as Ideal of L;
ZZ: a in (.a.>;
ZL: P c= P \/ (.a.> by XBOOLE_1:7;
ZK: (.a.> c= P \/ (.a.> by XBOOLE_1:7;
ZM: P \/ (.a.> c= Pa by FILTER_2:def 9;
kk: D c= D \/ <.a.) by XBOOLE_1:7;
    D \/ <.a.) c= D1 by FILTER_0:def 4; then
hh: D c= D1 by kk;
zx: not a in P by HH,W0,XBOOLE_0:3;
    not Top L in Pa
    proof
      assume
f2:   Top L in Pa;
      (.P \/ (.a.>.> = { r where r is Element of L :
        ex p,q being Element of L st r [= p"\/"q & p in P & q in (.a.> }
          by FILTER_2:49; then
      consider r being Element of L such that
F3:   r = Top L &
      ex p,q being Element of L st r [= p"\/"q & p in P & q in (.a.>
        by f2;
      consider p,q being Element of L such that
F4:   Top L [= p "\/" q & p in P & q in (.a.> by F3;
F5:   Top L [= p "\/" a by FILTER_0:1,F4,FILTER_2:28;
      p in { x where x is Element of L : a "\/" x = Top L } by F5;
      hence thesis by hh,XBOOLE_0:3,F4,W0;
    end; then
    consider QQ being Ideal of L such that
W1: QQ is prime & Pa c= QQ & not Top L in QQ by Cor16;
    QQ <> the carrier of L by W1; then
w1: QQ is proper by SUBSET_1:def 6;
W2: P in Spectrum L & QQ in Spectrum L by W0,W1,w1,w0;
W3: P <> QQ by zx,W1,ZM,ZZ,ZK;
    P c= QQ by W1,ZL,ZM; then
    P, QQ are_c=-comparable;
    hence thesis by d1,W2,W3;
  end;
