reserve x for set,
  i,j,k,n for Nat,
  K for Field;
reserve a,b,c,d for Element of K;
reserve D for non empty set;

theorem Th34:
  for p being Permutation of Seg 3 st p = <* 3,1,2 *> holds not p
  is being_transposition
proof
  let p be Permutation of Seg 3;
  assume
A1: p = <*3,1,2*>;
  then
A2: dom p = {1,2,3} by FINSEQ_1:89,FINSEQ_3:1;
  not ex i,j st i in dom p & j in dom p & i <> j & p.i = j & p.j = i & for
  k st k <> i & k <> j & k in dom p holds p.k = k
  proof
    given i,j such that
A3: i in dom p and
A4: j in dom p & i <> j and
    p.i = j and
    p.j = i and
A5: for k st k <> i & k <> j & k in dom p holds p.k = k;
    ex k being Element of NAT st k <> i & k <> j & k in dom p
    proof
A6:   i = 1 or i = 2 or i = 3 by A2,A3,ENUMSET1:def 1;
      per cases by A2,A4,A6,ENUMSET1:def 1;
      suppose
A7:     i = 1 & j = 2;
        take 3;
        thus thesis by A2,A7,ENUMSET1:def 1;
      end;
      suppose
A8:     i = 2 & j = 3;
        take 1;
        thus thesis by A2,A8,ENUMSET1:def 1;
      end;
      suppose
A9:     i = 1 & j = 3;
        take 2;
        thus thesis by A2,A9,ENUMSET1:def 1;
      end;
      suppose
A10:    i = 2 & j = 1;
        take 3;
        thus thesis by A2,A10,ENUMSET1:def 1;
      end;
      suppose
A11:    i = 3 & j = 1;
        take 2;
        thus thesis by A2,A11,ENUMSET1:def 1;
      end;
      suppose
A12:    i = 3 & j = 2;
        take 1;
        thus thesis by A2,A12,ENUMSET1:def 1;
      end;
    end;
    then consider k such that
A13: k <> i & k <> j and
A14: k in dom p;
A15: p.k = k by A5,A13,A14;
    per cases by A2,A14,ENUMSET1:def 1;
    suppose
      k = 1;
      hence thesis by A1,A15;
    end;
    suppose
      k = 2;
      hence thesis by A1,A15;
    end;
    suppose
      k = 3;
      hence thesis by A1,A15;
    end;
  end;
  hence thesis by MATRIX_1:def 14;
end;
