
theorem Th34:
for X1,X2 be non empty set, x be Element of X1, y be Element of X2,
 A be Subset of [:X1,X2:], f be PartFunc of [:X1,X2:],ExtREAL
 holds ProjPMap1(f|A,x) = ProjPMap1(f,x)|X-section(A,x)
     & ProjPMap2(f|A,y) = ProjPMap2(f,y)|Y-section(A,y)
proof
    let X1,X2 be non empty set, x be Element of X1, y be Element of X2,
    A be Subset of [:X1,X2:], f be PartFunc of [:X1,X2:],ExtREAL;
    set f1 = f|A;

A2: dom f /\ A c= dom f by XBOOLE_1:17;

A4: dom f1 = dom f /\ A by RELAT_1:61;

A7: dom(ProjPMap1(f,x)|X-section(A,x))
    = dom(ProjPMap1(f,x)) /\ X-section(A,x) by RELAT_1:61
   .= X-section(dom f,x) /\ X-section(A,x) by Def3
   .= X-section(dom f /\ A,x) by MEASUR11:27
   .= dom(ProjPMap1(f1,x)) by A4,Def3;

    now let y be Element of X2;
     assume y in dom(ProjPMap1(f1,x)); then
A8:  y in X-section(dom f /\ A,x) by A4,Def3; then
A9:  [x,y] in dom f /\ A by Th25; then
     ProjPMap1(f1,x).y = f1.(x,y) by A4,Def3; then
A10: ProjPMap1(f1,x).y = f.(x,y) by A9,FUNCT_1:48;
b3:  ProjPMap1(f,x).y = f.(x,y) by A2,A9,Def3;
     y in X-section(dom f,x) /\ X-section(A,x) by A8,MEASUR11:27; then
     y in X-section(A,x) by XBOOLE_0:def 4;
     hence (ProjPMap1(f1,x)).y = (ProjPMap1(f,x))|(X-section(A,x)).y
       by A10,b3,FUNCT_1:49;
    end;
    hence ProjPMap1(f1,x) = (ProjPMap1(f,x))|(X-section(A,x))
      by A7,PARTFUN1:5;

A13:dom(ProjPMap2(f,y)|Y-section(A,y))
    = dom(ProjPMap2(f,y)) /\ Y-section(A,y) by RELAT_1:61
   .= Y-section(dom f,y) /\ Y-section(A,y) by Def4
   .= Y-section(dom f /\ A,y) by MEASUR11:27
   .= dom(ProjPMap2(f1,y)) by A4,Def4;

    now let x be Element of X1;
     assume x in dom(ProjPMap2(f1,y)); then
A14: x in Y-section(dom f /\ A,y) by A4,Def4; then
A15: [x,y] in dom f /\ A by Th25; then
     ProjPMap2(f1,y).x = f1.(x,y) by A4,Def4; then
A16: ProjPMap2(f1,y).x = f.(x,y) by A15,FUNCT_1:48;
b4:  ProjPMap2(f,y).x = f.(x,y) by A2,A15,Def4;
     x in Y-section(dom f,y) /\ Y-section(A,y) by A14,MEASUR11:27; then
     x in Y-section(A,y) by XBOOLE_0:def 4;
     hence (ProjPMap2(f1,y)).x = (ProjPMap2(f,y))|(Y-section(A,y)).x
      by A16,b4,FUNCT_1:49;
    end;
    hence ProjPMap2(f1,y) = (ProjPMap2(f,y))|(Y-section(A,y))
      by A13,PARTFUN1:5;
end;
