reserve X for non empty set,
  Y for set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  f,g for PartFunc of X,COMPLEX,
  r for Real,
  k for Real,
  n for Nat,
  E for Element of S;

theorem Th34:
  for f,g be PartFunc of X,REAL st (ex E be Element of S st E =
  dom f & E= dom g & f is E-measurable & g is E-measurable) & f is
nonnegative & g is nonnegative & (for x be Element of X st x in dom g holds g.x
  <= f.x) holds Integral(M,g) <= Integral(M,f)
proof
  let f,g be PartFunc of X,REAL;
  assume that
A1: ex A be Element of S st A = dom f & A= dom g & f is A-measurable &
  g is A-measurable and
A2: f is nonnegative & g is nonnegative and
A3: for x be Element of X st x in dom g holds g.x <= f.x;
A4: Integral(M,g) = integral+(M,R_EAL g) & Integral(M,f) = integral+(M,R_EAL
  f) by A1,A2,MESFUNC6:82;
  consider A be Element of S such that
A5: A = dom f & A= dom g and
A6: f is A-measurable & g is A-measurable by A1;
  R_EAL f is A-measurable & R_EAL g is A-measurable by A6,MESFUNC6:def 1;
  hence thesis by A2,A3,A5,A4,MESFUNC5:85;
end;
