reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem Th35:
  for S,E,F,G be RealNormSpace,
      Z be Subset of S,
      B be Lipschitzian BilinearOperator of E,F,G,
      W be PartFunc of S,G,
      w be PartFunc of S,[:E,F:],
      u be PartFunc of S,E,
      v be PartFunc of S,F
   st u is_differentiable_on Z
    & v is_differentiable_on Z
    & W = B * w & w = <:u,v:>
  holds
    W is_differentiable_on Z
  & for x be Point of S st x in Z
    holds
      for ds be Point of S
      holds
        ((W`|Z)/.x).ds
       = B.(((u`|Z)/.x).ds, v/.x) + B.(u/.x, ((v`|Z)/.x).ds)
proof
  let S,E,F,G be RealNormSpace,
      Z be Subset of S,
      B be Lipschitzian BilinearOperator of E,F,G,
      W be PartFunc of S,G,
      w be PartFunc of S,[:E,F:],
      u be PartFunc of S,E,
      v be PartFunc of S,F;

  assume that
  A1: u is_differentiable_on Z and
  A2: v is_differentiable_on Z and
  A3: W = B * w & w = <:u,v:>;

  A4: w is_differentiable_on Z
    & ( for x be Point of S st x in Z
        holds (w`|Z)/.x = <:(u`|Z)/.x, (v`|Z)/.x:> )
    & for x be Point of S st x in Z
      holds
        for dx be Point of S
        holds
          ((w`|Z)/.x).dx
        = [((u`|Z)/.x).dx, ((v`|Z)/.x).dx] by A1,A2,A3,Th28;
  A5: B is_differentiable_on [#][:E,F:] by NDIFF12:14;

  w.:Z c= [#][:E,F:];
  hence A6: W is_differentiable_on Z by A3,A4,A5,Th19;

  A7: Z is open by NDIFF_1:32,A1;

  thus
  for x be Point of S st x in Z
  holds
    for ds be Point of S
    holds
      ((W`|Z )/.x).ds
      = B.(((u`|Z)/.x).ds, v/.x) + B.(u/.x, ((v`|Z)/.x).ds)
  proof
    let x be Point of S;
    assume A8: x in Z;
    then A9: u is_differentiable_in x by A1,A7,NDIFF_1:31;
    A10: v is_differentiable_in x by A2,A7,A8,NDIFF_1:31;

    let ds be Point of S;

    A11: diff(W,x).ds = B.(diff(u,x).ds,v/.x)+ B.(u/.x,diff(v,x).ds)
      by A3,A4,A8,A9,A10,Th34;
    A12: (W`|Z)/.x = diff(W,x) by A6,A8,NDIFF_1:def 9;
    (u`|Z)/.x = diff(u,x) by A1,A8,NDIFF_1:def 9;
    hence thesis by A2,A8,A11,A12,NDIFF_1:def 9;
  end;
end;
