reserve S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem NEIB1:
  for E be RealNormSpace,
      x,b be Point of E,
      N be Neighbourhood of x holds
  {z-b where z is Point of E: z in N} is Neighbourhood of x-b &
  {z+b where z is Point of E: z in N} is Neighbourhood of x+b
  proof
    let E be RealNormSpace,
        x,b be Point of E,
        N be Neighbourhood of x;
    consider g being Real such that
    A1: 0 < g
      & { y where y is Point of E : ||.(y - x).|| < g } c= N by NFCONT_1:def 1;
    set V = { y where y is Point of E : ||.(y - x).|| < g };
B2: {z-b where z is Point of E: z in N} c= the carrier of E
    proof
      let s be object;
      assume s in {z-b where z is Point of E: z in N}; then
      ex z be Point of E st s=z-b & z in N;
      hence s in the carrier of E;
    end;
B3: {z+b where z is Point of E: z in N} c= the carrier of E
    proof
      let s be object;
      assume s in {z+b where z is Point of E: z in N}; then
      ex z be Point of E st s=z+b & z in N;
      hence s in the carrier of E;
    end;
    {y where y is Point of E : ||.(y - (x-b) ).|| < g} c=
      {z-b where z is Point of E: z in N}
    proof
      let t be object;
      assume t in {y where y is Point of E : ||.(y - (x-b) ).|| < g}; then
      consider y be Point of E such that
      A4: t=y & ||.(y - (x-b) ).|| < g;
      (y - (x - b)) = (y - x) + b by RLVECT_1:29
        .= y + b - x by RLVECT_1:def 3; then
      A5: y + b in V by A4;
      y = (y + b) - b by RLVECT_4:1;
      hence t in {z-b where z is Point of E: z in N} by A1,A4,A5;
    end;
    hence {z-b where z is Point of E: z in N} is Neighbourhood of x-b
        by A1,B2,NFCONT_1:def 1;
    {y where y is Point of E : ||.(y - (x+b) ).|| < g} c=
      {z+b where z is Point of E: z in N}
    proof
      let t be object;
      assume t in {y where y is Point of E : ||.(y - (x+b) ).|| < g}; then
      consider y be Point of E such that
      A6: t = y & ||.(y - (x + b) ).|| < g;
      ||. (y - b) - x .|| < g by A6,RLVECT_1:27; then
      A7: y - b in V;
      y = (y - b) + b by RLVECT_4:1;
      hence t in {z + b where z is Point of E: z in N} by A1,A6,A7;
    end;
    hence {z + b where z is Point of E: z in N} is Neighbourhood of x + b
        by A1,B3,NFCONT_1:def 1;
  end;
