reserve A,A1,A2,B,C,D for Ordinal,
  X,Y for set,
  x,y,a,b,c for object,
  L,L1,L2,L3 for Sequence,
  f for Function;
reserve fi,psi for Ordinal-Sequence;

theorem Th34:
  A c= B implies A +^ C c= B +^ C
proof
  defpred P[Ordinal] means A +^ $1 c= B +^ $1;
  assume
A1: A c= B;
A2: for C st for D st D in C holds P[D] holds P[C]
  proof
    let C such that
A3: for D st D in C holds A +^ D c= B +^ D;
A4: now
      given D such that
A5:   C = succ D;
A6:   B +^ C = succ(B +^ D) by A5,Th28;
      A +^ D c= B +^ D & A +^ C = succ(A +^ D) by A3,A5,Th28,ORDINAL1:6;
      hence thesis by A6,Th1;
    end;
A7: now
      deffunc F(Ordinal) = A+^$1;
      assume that
A8:   C <> 0 and
A9:   for D holds C <> succ D;
      consider fi such that
A10:  dom fi = C & for D st D in C holds fi.D = F(D) from OSLambda;
A11:  now
        let D;
        assume D in rng fi;
        then consider x being object such that
A12:    x in dom fi and
A13:    D = fi.x by FUNCT_1:def 3;
        reconsider x as Ordinal by A12;
A14:    B +^ x in B +^ C by A10,A12,Th32;
        D = A+^x & A +^ x c= B +^ x by A3,A10,A12,A13;
        hence D in B +^ C by A14,ORDINAL1:12;
      end;
      C is limit_ordinal by A9,ORDINAL1:29;
      then A+^C = sup fi by A8,A10,Th29
        .= sup rng fi;
      hence thesis by A11,Th20;
    end;
    now
      assume
A15:  C = 0;
      then A +^ C = A by Th27;
      hence thesis by A1,A15,Th27;
    end;
    hence thesis by A4,A7;
  end;
  for C holds P[C] from ORDINAL1:sch 2(A2);
  hence thesis;
end;
